;============================================================================
; Faxanadu (U).nes
;
; PRG15_MIRROR ($c000 - $ffdf)
;============================================================================

.segment "PRG15_MIRROR"
.reloc

;============================================================================
; Write attribute data for the HUD to the PPU.
;
; The attribute data will be written from
; HUD_ATTRIBUTE_DATA_BY_INDEX based on the
; UI_AttributeDataIndex set when loading the
; screen.
;
; INPUTS:
;     UI_AttributeDataIndex:
;         The index into the lookup table for the current
;         screen.
;
;     HUD_ATTRIBUTE_DATA_BY_INDEX:
;         The lookup table of attribute data to write.
;
; OUTPUTS:
;     PPUADDR:
;         The updated PPU address.
;
;     PPUDATA:
;         The written data.
;
; CALLS:
;     UI_DrawHUD
;
; XREFS:
;     Screen_SetupNew
;============================================================================
[c000]UI_SetHUDPPUAttributes:
;
; Set the PPUADDR to 0x23C0, the top row where the status
; bar resides.
;
[c000]a9 23LDA #$23
[c002]8d 06 20STA a:PPUADDR; Set upper PPUADDR as 0x23.
[c005]a9 c0LDA #$c0
[c007]8d 06 20STA a:PPUADDR; Set upper PPUADDR as 0xC0.
[c00a]ae 8d 03LDX a:UI_AttributeDataIndex; X = HUD attribute data index, computed when setting up the screen.
[c00d]bd 1b c0LDA a:HUD_ATTRIBUTE_DATA_BY_INDEX,X; Load the value for the attribute data.


;
; Write 8 bytes based on data from the lookup table
; HUD_ATTRIBUTE_DATA_BY_INDEX at index
; UI_AttributeDataIndex.
;
[c010]a2 08LDX #$08; X = 8 (loop counter).

[c012]@_writeLoop:
[c012]8d 07 20STA a:PPUDATA; Write to the PPU.
[c015]caDEX; X--
[c016]d0 faBNE @_writeLoop; If X > 0, loop.


;
; Draw the HUD.
;
[c018]4c 58 c0JMP UI_DrawHUD; Jump to draw the HUD.


;============================================================================
; Attribute data used for the HUD.
;
; These are indexed by values from lookup table
; PALETTE_INDEX_TO_UI_BG_ATTRIBUTE_INDEX (stored in
; UI_AttributeDataIndex.
;
; Only values 0, 1, 2, and 3 are used.
;
; The rest seem to be unused, but many end up styled to
; better match regions of the game.
;
; XREFS:
;     UI_SetHUDPPUAttributes
;============================================================================

;
; XREFS:
;     UI_SetHUDPPUAttributes
;
[c01b]HUD_ATTRIBUTE_DATA_BY_INDEX:
[c01b]00.byte $00; [0]: Dartmoor, Castle of Fraternal, King Grieve's Room
[c01c]55.byte $55; [1]: Start Screen
[c01d]aa.byte $aa; [2]: Most exterior areas.
[c01e]ff.byte $ff; [3]: Most interior areas.
[c01f]41.byte $41; [4]: Here and below are unused.
[c020]20.byte $20; [5]:
[c021]04.byte $04; [6]:
[c022]07.byte $07; [7]:
[c023]08.byte $08; [8]:
[c024]09.byte $09; [9]:
[c025]0a.byte $0a; [10]:
[c026]61.byte $61; [11]:
[c027]20.byte $20; [12]:
[c028]04.byte $04; [13]:
[c029]0b.byte $0b; [14]:
[c02a]0c.byte $0c; [15]:
[c02b]0d.byte $0d; [16]:
[c02c]0e.byte $0e; [17]:
[c02d]56.byte $56; [18]:
[c02e]20.byte $20; [19]:
[c02f]03.byte $03; [20]:
[c030]0f.byte $0f; [21]:
[c031]10.byte $10; [22]:
[c032]11.byte $11; [23]:

;============================================================================
; DEADCODE
;============================================================================
[c033]DEADCODE_FUN_PRG15_MIRROR__c033:
[c033]a0 00LDY #$00
[c035]b1 02LDA (Temp_Addr_L),Y
[c037]85 e8STA PPU_TargetAddr
[c039]c8INY
[c03a]b1 02LDA (Temp_Addr_L),Y
[c03c]85 e9STA PPU_TargetAddr_U
[c03e]c8INY
[c03f]b1 02LDA (Temp_Addr_L),Y
[c041]48PHA
[c042]20 dc cfJSR PPUBuffer_QueueCommandOrLength
[c045]68PLA
[c046]85 00STA Temp_00
[c048]a0 03LDY #$03

[c04a]@LAB_PRG15_MIRROR__c04a:
[c04a]b1 02LDA (Temp_Addr_L),Y
[c04c]9d 00 05STA a:PPUBuffer,X
[c04f]e8INX
[c050]c8INY
[c051]c6 00DEC Temp_00
[c053]d0 f5BNE @LAB_PRG15_MIRROR__c04a
[c055]86 20STX PPUBuffer_WriteOffset
[c057]60RTS

;============================================================================
; Draw the player's state on the HUD UI.
;
; INPUTS:
;     Player_MP:
;         The player's current MP.
;
; OUTPUTS:
;     None
;
; CALLS:
;     UI_DrawTimeValue
;     UI_DrawGoldValue
;     UI_DrawPlayerExperience
;     UI_DrawPlayerHP
;     Player_SetMP
;     PPUBuffer_DrawAll
;
; XREFS:
;     UI_SetHUDPPUAttributes
;============================================================================
[c058]UI_DrawHUD:
[c058]a9 00LDA #$00
[c05a]20 90 f9JSR UI_DrawTimeValue; Draw the time value.
[c05d]20 e7 f9JSR UI_DrawGoldValue; Draw the gold value.
[c060]20 fb cfJSR PPUBuffer_DrawAll; Flush to the PPU.
[c063]20 75 f9JSR UI_DrawPlayerExperience; Draw the player experience value.
[c066]20 fb cfJSR PPUBuffer_DrawAll; Flush to the PPU.
[c069]20 fb cfJSR PPUBuffer_DrawAll; Flush to the PPU.
[c06c]20 bd c0JSR UI_DrawPlayerHP; Draw the player's HP bar.
[c06f]20 fb cfJSR PPUBuffer_DrawAll; Flush to the PPU.
[c072]ad 9a 03LDA a:Player_MP; Load the player's MP.
[c075]20 85 faJSR Player_SetMP; Set it and draw.
[c078]4c fb cfJMP PPUBuffer_DrawAll; Flush to the PPU.

;============================================================================
; Increase the player's HP.
;
; This will be capped to 80HP.
;
; INPUTS:
;     A:
;         The number of health points to add.
;
;     Player_HP_U:
;         The upper byte of player health to add to.
;
; OUTPUTS:
;     Player_HP_U:
;         The new upper byte of player health.
;
; CALLS:
;     UI_DrawPlayerHPValue
;
; XREFS:
;     Player_HandleTouchBread
;     Player_FillHPAndMP
;     Player_UseRedPotion
;============================================================================
[c07b]Player_AddHP:
;
; Update the player's HP with the provided value.
;
[c07b]18CLC; Clear carry so it's not added.
[c07c]6d 31 04ADC a:Player_HP_U; Add the provided HP to the player's health.
[c07f]8d 31 04STA a:Player_HP_U; Store as the new health.


;
; Check against the cap.
;
[c082]c9 50CMP #$50; Cap at 80 HP.
[c084]90 05BCC @_drawHP; Jump if it's under.
[c086]a9 50LDA #$50; Else, cap it to 80HP.
[c088]8d 31 04STA a:Player_HP_U; Store as the new health.

[c08b]@_drawHP:
[c08b]4c 75 faJMP UI_DrawPlayerHPValue

;============================================================================
; Decrease the player's HP.
;
; If the HP hits <= 0, and an elixir is in the inventory, it will be used.
; If it hits <= 0 and there's no elixir, the player will die.
;
; INPUTS
;     Player_HP_U:
;     Player_HP_L:
;         The player's current health.
;
;     Arg_PlayerHealthDelta_U:
;     Arg_PlayerHealthDelta_L:
;         The health to add.
;
;     SpecialItems:
;         The player's current special items.
;
; OUTPUTS:
;     Player_HP_U:
;     Player_HP_L:
;         The new player health.
;
;     PlayerIsDead:
;         Set to 1 if the player dies.
;
; CALLS:
;     UI_DrawPlayerHP
;     Player_UseElixir
;
; XREFS:
;     Player_ApplyDamage
;     Player_HandleHitByMagic
;     SpriteBehavior_FlashScreenHitPlayer
;============================================================================
[c08e]Player_ReduceHP:
;
; Reduce the lower byte of player health.
;
[c08e]ad 32 04LDA a:Player_HP_L; Load the lower byte of the player's health.
[c091]38SEC
[c092]ed bc 04SBC a:Arg_PlayerHealthDelta_L; Subtract the specified lower byte of health.
[c095]8d 32 04STA a:Player_HP_L; Store it as the new player health.


;
; Reduce the upper byte of player health.
;
[c098]ad 31 04LDA a:Player_HP_U; Load the upper byte of the player's health.
[c09b]ed bd 04SBC a:Arg_PlayerHealthDelta_U; Subtract the specified upper byte of health.
[c09e]8d 31 04STA a:Player_HP_U; Store it as the new player health.
[c0a1]b0 17BCS @_isStillAlive; If there's still health left, the player is still alive.


;
; The player is out of health. They may die.
;
[c0a3]a9 00LDA #$00
[c0a5]8d 31 04STA a:Player_HP_U; Set the player's upper byte of health to 0.
[c0a8]20 bd c0JSR UI_DrawPlayerHP; Draw the health.


;
; Check if the player has an elixir before killing them.
;
[c0ab]ad 2c 04LDA a:SpecialItems; Load the player's special items.
[c0ae]29 08AND #$08; Check if the player has an elixir.
[c0b0]f0 03BEQ @_killPlayer; If not, kill the player.


;
; The player has an elixir. Fill up their health instead
; of killing the player.
;
[c0b2]4c ca c4JMP Player_UseElixir; Use the Elixir.


;
; Mark the player as dead.
;
[c0b5]@_killPlayer:
[c0b5]a9 01LDA #$01; Mark the player as dead.
[c0b7]8d 38 04STA a:PlayerIsDead; Store that.


;
; Draw the player's health.
;
[c0ba]@_isStillAlive:
[c0ba]4c bd c0JMP UI_DrawPlayerHP; Draw player health.

;============================================================================
; Draw the player's health.
;
; INPUTS:
;     Player_HP_U:
;         The full value of the player's health.
;
; OUTPUTS:
;     None
;
; CALLS:
;     UI_DrawPlayerHPValue
;
; XREFS:
;     Player_ReduceHP
;     Player_UseHourGlass
;     UI_DrawHUD
;============================================================================
[c0bd]UI_DrawPlayerHP:
[c0bd]ad 31 04LDA a:Player_HP_U; Load the player's current health.
[c0c0]4c 75 faJMP UI_DrawPlayerHPValue; Draw it.

;============================================================================
; Decrement the MP for a spell.
;
; This will look at the selected magic type and deduct the
; cost from the player's total MP if there's enough to cast.
;
; INPUTS:
;     Player_MP:
;         The player's current MP.
;
;     SelectedMagic:
;         The selected magic.
;
;     MAGIC_COSTS:
;         The table of magic costs per spell.
;
; OUTPUTS:
;     C:
;         0 = Cost deducted for the spell.
;         1 = Not enough MP for the spell.
;
;     Player_MP:
;         The new MP amount.
;
; CALLS:
;     Player_SetMP
;
; XREFS:
;     Player_CastMagic
;============================================================================
[c0c3]Player_ReduceMP:
[c0c3]ae c0 03LDX a:SelectedMagic; Load the selected magic spell.
[c0c6]ad 9a 03LDA a:Player_MP; Load the player's total MP.
[c0c9]38SEC
[c0ca]fd a9 b7SBC a:MAGIC_COSTS,X; Look up the cost of this spell.
[c0cd]90 08BCC @_notEnoughMP; If there's not enough MP for the spell, then jump.


;
; The player has enough MP for the spell.
;
[c0cf]8d 9a 03STA a:Player_MP; Else, store the reduced MP.
[c0d2]20 85 faJSR Player_SetMP; Set that on the player and draw.
[c0d5]18CLC; Clear the carry flag to indicate a success.
[c0d6]60RTS


;
; The player does not have enough mana.
;
[c0d7]@_notEnoughMP:
[c0d7]38SEC; Set the carry flag to 1 to indicate not enough MP.
[c0d8]60RTS

;============================================================================
; Add points to the player's MP.
;
; This will be capped to 80 points.
;
; INPUTS:
;     A:
;         The MP to add.
;
;     Player_MP:
;         The player's current MP.
;
; OUTPUTS:
;     Player_MP:
;         The new MP.
;
; CALLS:
;     Player_SetMP
;
; XREFS:
;     Player_FillHPAndMP
;============================================================================
[c0d9]Player_AddMP:
;
; Add the provided MP to the player's MP.
;
[c0d9]18CLC; Clear carry so it's not added.
[c0da]6d 9a 03ADC a:Player_MP; Add to the player's  MP.
[c0dd]8d 9a 03STA a:Player_MP; Store it.
[c0e0]c9 50CMP #$50; Check if it's > 80 points.
[c0e2]90 05BCC @_drawMP; If we're under the cap, return.


;
; Cap the MP to the total allowed amount.
;
[c0e4]a9 50LDA #$50; Cap to 80 points.


;
; Store it.
;
[c0e6]8d 9a 03STA a:Player_MP

[c0e9]@_drawMP:
[c0e9]4c 85 faJMP Player_SetMP; Set the player's mana points and draw.

;============================================================================
; NOTE: This is used exclusively by the Unknown 29 sprite behavior.
;
; XREFS:
;     SpriteBehavior_Unknown_29_SomeSetup
;============================================================================
[c0ec]Player_Something_ChangeHP:
[c0ec]8aTXA
[c0ed]48PHA
[c0ee]a9 00LDA #$00
[c0f0]8d c0 04STA a:Temp1_SomethingChangedHP
[c0f3]8d c1 04STA a:Temp2_SomethingChangedHP
[c0f6]a2 10LDX #$10
[c0f8]2e bc 04ROL a:Arg_PlayerHealthDelta_L
[c0fb]2e bd 04ROL a:Arg_PlayerHealthDelta_U

[c0fe]@LAB_PRG15_MIRROR__c0fe:
[c0fe]2e c0 04ROL a:Temp1_SomethingChangedHP
[c101]2e c1 04ROL a:Temp2_SomethingChangedHP
[c104]ad c0 04LDA a:Temp1_SomethingChangedHP
[c107]cd be 04CMP a:SpriteBehaviorUnknown20_SomethingXOrY
[c10a]ad c1 04LDA a:Temp2_SomethingChangedHP
[c10d]ed bf 04SBC a:BYTE_04bf
[c110]90 12BCC @LAB_PRG15_MIRROR__c124
[c112]ad c0 04LDA a:Temp1_SomethingChangedHP
[c115]ed be 04SBC a:SpriteBehaviorUnknown20_SomethingXOrY
[c118]8d c0 04STA a:Temp1_SomethingChangedHP
[c11b]ad c1 04LDA a:Temp2_SomethingChangedHP
[c11e]ed bf 04SBC a:BYTE_04bf
[c121]8d c1 04STA a:Temp2_SomethingChangedHP

[c124]@LAB_PRG15_MIRROR__c124:
[c124]2e bc 04ROL a:Arg_PlayerHealthDelta_L
[c127]2e bd 04ROL a:Arg_PlayerHealthDelta_U
[c12a]caDEX
[c12b]d0 d1BNE @LAB_PRG15_MIRROR__c0fe
[c12d]68PLA
[c12e]aaTAX
[c12f]60RTS

;============================================================================
; Clear sprite state.
;
; This will clear out all the current sprites and the
; selected weapon, and reset the screen color mode.
;
; INPUTS:
;     PPU_Mask:
;         The current screen color mode.
;
; OUTPUTS:
;     CurrentSprites_Entities:
;         The cleared sprite entities.
;
;     CurrentSprites_HP:
;         The cleared sprite HPs.
;
;     CurrentSprites_HitCounter:
;         The cleared sprite hit counters.
;
;     CurrentSprites_Behaviors:
;         The cleared sprite subtypes.
;
;     PPU_Mask:
;         The new color mode with greyscale removed.
;
;     IScript_PortraitID:
;         Set to 0xFF.
;
; CALLS:
;     CurrentSprite_ResetPPUTileOffset
;
; XREFS:
;     EndGame_Begin
;     Game_MainLoop
;     Player_HandleDeath
;     Screen_SetupSprites
;============================================================================
[c130]Screen_ClearSprites:
[c130]a2 07LDX #$07; X = 7 (loop counter -- looping 8 times)

[c132]@_clearSpritesLoop:
[c132]a9 ffLDA #$ff
[c134]9d cc 02STA a:CurrentSprites_Entities,X; Set sprite to 0xFF (cleared).
[c137]a9 00LDA #$00
[c139]9d 44 03STA a:CurrentSprites_HP,X; Set sprite hit points to 0.
[c13c]9d 4c 03STA a:CurrentSprites_HitCounter,X; Set sprite hit counter to 0.
[c13f]9d d4 02STA a:CurrentSprites_Behaviors,X; Set sprite subtype to 0.
[c142]caDEX; X--
[c143]10 edBPL @_clearSpritesLoop; If we're not done, loop.


;
; We're out of the loop. Reset the PPU draw offset and restore
; screen state.
;
[c145]20 6f cdJSR CurrentSprite_ResetPPUTileOffset; Reset the PPU offset.
[c148]a9 ffLDA #$ff
[c14a]8d c7 03STA a:IScript_PortraitID; Clear any portrait shown on screen.
[c14d]a5 0bLDA PPU_Mask; Load the current screen color mode.
[c14f]29 feAND #$fe; Set to color mode (clear bit 1)
[c151]85 0bSTA PPU_Mask; Store the new color mode.
[c153]60RTS

;============================================================================
; Load extra information about the contents of the screen.
;
; This may include data such as sprite values, NPC IScript
; entrypoints, and special screen events (such as boss kill
; triggers).
;
; INPUTS:
;     Area_CurrentArea:
;         The area being loaded.
;
;     Area_CurrentScreen:
;         The screen being loaded within the area.
;
;     AREA_SPRITE_ADDRESSES:
;         The table of areas to screen lists.
;
; OUTPUTS:
;     Sprites_ReadInfoAddr:
;         The starting read address for the screen info.
;
;     CurrentScreen_SpecialEventID:
;         The screen's loaded special event ID (0xFF if
;         there is none).
;
;     Screen_ExtraInfoAddr:
;     Temp_Addr_L:
;         Used internally and clobbered.
;
; CALLS:
;     Screen_LoadSpecialEventID
;
; XREFS:
;     Screen_LoadSpriteInfo
;============================================================================
[c154]Screen_LoadAllScreenInfo:
;
; Set the address of the sprites-for-screen lookup table
; for the area.
;
[c154]a5 24LDA Area_CurrentArea; A = Current area index.
[c156]0aASL A; Convert to a word offset for the lookup table.


;
; Set the starting address of the screen data.
;
[c157]a8TAY; Y = A
[c158]b9 10 82LDA a:AREA_SPRITE_ADDRESSES,Y; Load the upper byte of the address.
[c15b]85 02STA Temp_Addr_L; Store for reading.
[c15d]b9 11 82LDA a:AREA_SPRITE_ADDRESSES+1,Y; Load the lower byte of the address.
[c160]85 03STA Temp_Addr_U; Store it.


;
; Check the first byte of the address. If 0xFF,
; nothing will be loaded.
;
[c162]a0 01LDY #$01; Y = 1
[c164]b1 02LDA (Temp_Addr_L),Y; Load the address for the screens list.
[c166]c9 ffCMP #$ff; Is it 0xFF?
[c168]f0 49BEQ RETURN_C1B3; If so, there's nothing to load. Return.


;
; Set the start address for a screen's sprite and metadata
; information.
;
[c16a]a5 63LDA Area_CurrentScreen; A = Current screen index.
[c16c]0aASL A; Convert to a word offset for the lookup table.
[c16d]a8TAY; Y = A


;
; Read the address for the screen information.
;
[c16e]b1 02LDA (Temp_Addr_L),Y; Load the lower byte of the screen address.
[c170]85 caSTA Sprites_ReadInfoAddr; Store it as the lower byte of the of the sprites read address.
[c172]c8INY; Y++
[c173]b1 02LDA (Temp_Addr_L),Y; Load the upper byte.
[c175]85 cbSTA Sprites_ReadInfoAddr_U; And store it.


;
; Find the end of the sprites list for the screen.
;
; Sprites are in 2-byte pairs of (Entity ID, Sprite Value).
; This will skip those bytes until the end of the list is
; hit.
;
[c177]a0 00LDY #$00; Y = 0

[c179]@_readLoop:
[c179]b1 caLDA (Sprites_ReadInfoAddr),Y; Load the next byte from the screen data.
[c17b]c9 ffCMP #$ff; Is it 0xFF?
[c17d]d0 10BNE @_prepareNextLoopIter; If not, jump to prepare for the next loop


;
; The sprite information is 0xFF, so we're done looping.
; Read the screen information.
;
[c17f]c8INY; Y++
[c180]98TYA; A = Y
[c181]18CLC
[c182]65 caADC Sprites_ReadInfoAddr; Increment the read address by 2 bytes.
[c184]85 ccSTA Screen_ExtraInfoAddr
[c186]a5 cbLDA Sprites_ReadInfoAddr_U; Load the upper byte.
[c188]69 00ADC #$00; Add carry, if lower byte overflowed.
[c18a]85 cdSTA Screen_ExtraInfoAddr_U; Store as the new upper byte.
[c18c]4c 99 c1JMP Screen_LoadSpecialEventID; Read the extra screen information.


;
; Increment by 2 (the sprite entity and value).
;
[c18f]@_prepareNextLoopIter:
[c18f]c8INY; Y++
[c190]c8INY; Y++
[c191]d0 e6BNE @_readLoop; If Y > 0, loop.

;
; v-- Fall through --v
;

;============================================================================
; Clear the special event ID for the current screen.
;
; This disables any custom logic specific to certain screens.
;
; INPUTS:
;     None.
;
; OUTPUTS:
;     CurrentScreen_SpecialEventID:
;         Set to 0xFF (unset).
;
; XREFS:
;     Screen_LoadSpecialEventID
;============================================================================
[c193]Screen_SetNoSpecialEventID:
;
; No special event information was found for the screen.
; Clear that state (set to 0xFF).
;
[c193]a9 ffLDA #$ff
[c195]8d 2e 04STA a:CurrentScreen_SpecialEventID; Clear the special event ID (0xFF).
[c198]60RTS

;============================================================================
; Load extra information about the current screen.
;
; Screens may contain a special event ID, which adds custom
; logic to perform on each tick on a screen. This is used
; for three things:
;
; 1. Managing the pushable block status on the path to
;    Mascon.
; 2. Boss battle logic.
; 3. Final boss logic.
;
; INPUTS:
;     Screen_ExtraInfoAddr:
;     Screen_ExtraInfoAddr+1:
;         The address containing the extra screen
;         information.
;
; OUTPUTS:
;     CurrentScreen_SpecialEventID:
;         The special event ID loaded from the screen info,
;         or 0xFF (unset) if not found.
;
; XREFS:
;     Screen_LoadAllScreenInfo
;============================================================================
[c199]Screen_LoadSpecialEventID:
;
; Begin scanning for a 0xFF in the screen information. This
; will indicate the start of extra information for the screen
; (special screen event states, IScripts entrypoint references).
;
[c199]a0 00LDY #$00; Y = 0 (loop counter)

[c19b]@_scanLoop:
[c19b]b1 ccLDA (Screen_ExtraInfoAddr),Y; Load the next byte in the screen info data.
[c19d]c9 ffCMP #$ff; Is it 0xFF?
[c19f]d0 0eBNE @_noFFMarker; If so, we found the start of the extra data to load. Jump.


;
; We found the start of the extra info for the screen. We're
; looking for 0x80, which indicates special event code will
; run on this screen every tick. The type of event will be
; indicated in the following byte.
;
; An example of this would be running code when a boss is
; defeated, producing an item.
;
[c1a1]c8INY; Y++
[c1a2]b1 ccLDA (Screen_ExtraInfoAddr),Y; Load the next byte to see what we're working with.
[c1a4]c9 80CMP #$80; Is it 0x80?
[c1a6]d0 ebBNE Screen_SetNoSpecialEventID; If not, then we won't be running special event code on this screen.


;
; This screen runs special event code. Load it.
;
[c1a8]c8INY; Y++
[c1a9]b1 ccLDA (Screen_ExtraInfoAddr),Y; Load the next byte containing the special event ID.
[c1ab]8d 2e 04STA a:CurrentScreen_SpecialEventID; Store it while on the screen.
[c1ae]60RTS

[c1af]@_noFFMarker:
[c1af]c8INY; Y++


;
; If we hit 256 loops, we're done.
;
[c1b0]d0 e9BNE @_scanLoop; If we haven't wrapped, then loop.
[c1b2]60RTS; Else, we're done.

;
; XREFS:
;     Screen_LoadAllScreenInfo
;
[c1b3]RETURN_C1B3:
[c1b3]60RTS

;============================================================================
; Load information on a sprite from the screens list.
;
; This will read the next sprite entity ID in the screen
; information, followed by the block X/Y position where
; the sprite should be placed.
;
; INPUTS:
;     CurrentROMBank:
;         The current ROM bank.
;
;     Sprites_ReadInfoAddr:
;     Sprites_ReadInfoAddr+1:
;         The address in the screens table to read from.
;
; OUTPUTS:
;     CurrentSprite_Entity:
;         The loaded sprite entity ID.
;
;     CurrentSprite_XPos:
;         The loaded block X position of the sprite.
;
;     CurrentSprite_YPos:
;         The loaded block Y position of the sprite.
;
;     Sprites_ReadInfoAddr:
;     Sprites_ReadInfoAddr+1:
;         The updated address in the screens table to read
;         from.
;
; CALLS:
;     Screen_LoadAllScreenInfo
;     Sprites_PopulateNextAvailableSprite
;     MMC1_UpdateROMBank
;     MMC1_UpdatePRGBankToStackA
;
; XREFS:
;     Game_MainLoop
;     Screen_SetupSprites
;============================================================================
[c1b4]Screen_LoadSpriteInfo:
;
; Switch to ROM bank 11, where sprite information lives.
;
[c1b4]ad 00 01LDA a:CurrentROMBank; Load the current ROM bank.
[c1b7]48PHA; Push it to the stack.
[c1b8]a2 0bLDX #$0b
[c1ba]20 1a ccJSR MMC1_UpdateROMBank; Switch to bank 11.


;
; Load all the sprites for this screen.
;
[c1bd]20 54 c1JSR Screen_LoadAllScreenInfo; Load the sprite information for the screen.


;
; Switch bank to our previous bank.
;
[c1c0]68PLA; Pop A (our saved bank).
[c1c1]aaTAX; X = A
[c1c2]20 1a ccJSR MMC1_UpdateROMBank; And switch back to it.


;
; Begin our loop for reading all sprites for the screen.
;
[c1c5]@_readSpriteLoop:
[c1c5]a0 00LDY #$00; Y =  0 (info read offset)


;
; Switch back to ROM bank 11 (sprite info).
;
[c1c7]ad 00 01LDA a:CurrentROMBank; A = current ROM bank
[c1ca]48PHA; Push to the stack.
[c1cb]a2 0bLDX #$0b
[c1cd]20 1a ccJSR MMC1_UpdateROMBank; Switch to bank 11.


;
; Read information on the next sprite on the screen.
;
[c1d0]b1 caLDA (Sprites_ReadInfoAddr),Y; Read the current byte of the screen information.
[c1d2]c9 ffCMP #$ff; Is it 0xFF (our end-of-sprites list)?
[c1d4]f0 2cBEQ @_restoreBankAndReturn; If it is, we're done. Restore our bank and return.


;
; Store the sprite's entity ID.
;
[c1d6]8d 8b 03STA a:CurrentSprite_Entity; Store this byte as the sprite entity ID.


;
; Load the sprite's Y block position.
;
; This will be the upper nibble of the byte following the
; sprite entity ID.
;
[c1d9]c8INY; Y++
[c1da]b1 caLDA (Sprites_ReadInfoAddr),Y; Load the next byte.
[c1dc]29 f0AND #$f0; Take only the upper nibble.
[c1de]8d 8a 03STA a:CurrentSprite_YPos; Store it as the sprite's starting Y position.


;
; Load the sprite's X block position.
;
; This will be the lower nibble, which will then be placed
; in the upper nibble.
;
[c1e1]b1 caLDA (Sprites_ReadInfoAddr),Y; Load the same byte.
[c1e3]0aASL A; Shift the X coordinate from the lower nibble to the upper nibble.
[c1e4]0aASL A
[c1e5]0aASL A
[c1e6]0aASL A
[c1e7]8d 89 03STA a:CurrentSprite_XPos; Store as the sprite's X position.


;
; Restore our bank.
;
[c1ea]68PLA; Pull A (the saved bank) from the stack.
[c1eb]aaTAX; X = A
[c1ec]20 1a ccJSR MMC1_UpdateROMBank; And switch back to it.


;
; Finish processing this sprite. We'll add to the next
; available slot and fill in any information needed based
; on what we loaded.
;
[c1ef]20 05 c2JSR Sprites_PopulateNextAvailableSprite; Add this sprite to the next available slot.


;
; Increment the read address for the next sprite in the
; screen data.
;
[c1f2]a5 caLDA Sprites_ReadInfoAddr; A = lower byte of the screen information address
[c1f4]18CLC
[c1f5]69 02ADC #$02; Increment by 2 (sprite entity ID and position).
[c1f7]85 caSTA Sprites_ReadInfoAddr; Store as the new lower byte of the address.
[c1f9]a5 cbLDA Sprites_ReadInfoAddr_U; A = upper byte of the screen information address
[c1fb]69 00ADC #$00; Add carry if the lower byte overflowed.
[c1fd]85 cbSTA Sprites_ReadInfoAddr_U; Store it as the new upper byte of the address.
[c1ff]4c c5 c1JMP @_readSpriteLoop; Loop to read the next sprite.

[c202]@_restoreBankAndReturn:
[c202]4c d6 f3JMP MMC1_UpdatePRGBankToStackA

;============================================================================
; Populate the loaded sprite in the next available slot.
;
; This will set the default state of the sprite, the
; sprite's HP, hitbox type, subtype, and behavior
; addresses.
;
; If the sprite can't fit on the screen, it will not be
; loaded.
;
; INPUTS:
;     CurrentSprite_Entity:
;         The loaded sprite entity ID.
;
;     CurrentSprite_XPos:
;         The loaded block X position.
;
;     CurrentSprite_YPos:
;         The loaded block Y position.
;
; OUTPUTS:
;     CurrentSprites_Entities:
;         The updated sprite entities.
;
;     CurrentSprites_Flags:
;         The updated sprite flags.
;
;     CurrentSprites_Phases:
;         The updated sprite phases.
;
;     CurrentSprites_HitByMagicBehavior:
;         The updated behaviors when hit by magic.
;
;     CurrentSprites_XPos_Full:
;         The updated sprite X positions.
;
;     CurrentSprites_YPos:
;         The updated sprite Y positions.
;
;     CurrentSprites_HitBoxTypes:
;         The updated sprite hit box types.
;
;     CurrentSprites_HP:
;         The updated sprite HPs.
;
;     CurrentSprites_BehaviorAddrs_L:
;         The updated sprite behavior address lower bytes.
;
;     CurrentSprites_BehaviorAddrs_U:
;         The updated sprite behavior address upper bytes.
;
;     CurrentSprites_Behaviors:
;         The updated sprite subtypes.
;
; CALLS:
;     Sprites_LoadSpriteValue
;
; XREFS:
;     Screen_LoadSpriteInfo
;============================================================================
[c205]Sprites_PopulateNextAvailableSprite:
;
; Prepare the sprite loop.
;
[c205]a2 07LDX #$07; 7 = loop counter

[c207]@_loop:
[c207]8e 78 03STX a:CurrentSpriteIndex; Set it
[c20a]bd cc 02LDA a:CurrentSprites_Entities,X; Load the sprite entity at this index.
[c20d]c9 ffCMP #$ff; Is it 0xFF (unset)?
[c20f]d0 41BNE @_prepareNextIter; If not, jump to prepare for next loop.


;
; This sprite index is unset. Populate it.
;
[c211]a9 00LDA #$00; 0 = unset
[c213]9d e4 02STA a:CurrentSprites_Phases,X; Clear the sprite phase.
[c216]9d dc 02STA a:CurrentSprites_Flags,X; Clear the sprite flags.
[c219]a9 ffLDA #$ff; 0xFF = unset
[c21b]9d 34 03STA a:CurrentSprites_HitByMagicBehavior,X; Clear the hit by magic behavior.


;
; Set the sprite's starting X/Y position.
;
[c21e]ad 89 03LDA a:CurrentSprite_XPos; Load the current sprite X position to set.
[c221]95 baSTA CurrentSprites_XPos_Full,X; Set for the sprite index.
[c223]ad 8a 03LDA a:CurrentSprite_YPos; Load the Y position.
[c226]95 c2STA CurrentSprites_YPos,X; Set for the sprite index.
[c228]ad 8b 03LDA a:CurrentSprite_Entity; Load the sprite entity.
[c22b]9d cc 02STA a:CurrentSprites_Entities,X; Set it.
[c22e]a8TAY; Y = A (entity)
[c22f]b9 df b4LDA a:SPRITE_ENTITIES_HITBOX_TYPES,Y; Load the hitbox type for the entity.
[c232]9d 04 03STA a:CurrentSprites_HitBoxTypes,X; Set it.
[c235]b9 a9 b5LDA a:SPRITE_ENTITIES_HP,Y; Load the HP for the entity.
[c238]9d 44 03STA a:CurrentSprites_HP,X; Set it.


;
; Prepare the behavior scripts for the entity.
;
[c23b]98TYA; A = Y (entity)
[c23c]0aASL A; Convert to a word boundary.
[c23d]a8TAY; Y = A
[c23e]b9 2d adLDA a:SPRITE_BSCRIPTS,Y; Load the lower byte of the behavior script for the entity.
[c241]9d 54 03STA a:CurrentSprites_BehaviorAddrs_L,X; Set the lower byte of the address.
[c244]b9 2e adLDA a:SPRITE_BSCRIPTS+1,Y; Load the upper byte.
[c247]9d 5c 03STA a:CurrentSprites_BehaviorAddrs_U,X; Set the upper byte.
[c24a]a9 ffLDA #$ff; A = 0xFF (unset)
[c24c]9d d4 02STA a:CurrentSprites_Behaviors,X; Clear the current behavior state.
[c24f]4c 5b c2JMP Sprites_LoadSpriteValue; Load the value for the sprite and return.

[c252]@_prepareNextIter:
[c252]ae 78 03LDX a:CurrentSpriteIndex; X = current sprite index.
[c255]caDEX; X--
[c256]10 afBPL @_loop; If >= 0, loop.
[c258]60RTS


;============================================================================
; Banks storing the images for a range of sprites.
;
; XREFS:
;     Sprites_StoreBankForCurrentSprite
;============================================================================

;
; XREFS:
;     Sprites_StoreBankForCurrentSprite
;
[c259]SPRITE_IMAGE_BANKS:
[c259]06.byte $06; [0]: Bank for sprites 0-54

;
; XREFS:
;     Sprites_StoreBankForCurrentSprite
;
[c25a]SPRITE_IMAGE_BANKS_1_:
[c25a]07.byte $07; [1]: Bank for sprites 55-100

;============================================================================
; Load the value for a sprite from the screen's sprite info table.
;
; This loads the value information associated with a sprite
; on the screen. This may represent a message ID or some
; other value, depending on the sprite and situation.
;
; INPUTS:
;     X:
;         The sprite index to load the value for,
;
;     CurrentROMBank:
;         The currently-loaded ROM bank.
;
;     Screen_ExtraInfoAddr:
;     Screen_ExtraInfoAddr+1:
;         The current address for the extra sprite values
;         on the screen.
;
; OUTPUTS:
;     CurrentSprites_Values:
;         The updated sprite values.
;
;     Screen_ExtraInfoAddr:
;     Screen_ExtraInfoAddr+1:
;         The incremented address for the extra sprite
;         values on the screen.
;
; CALLS:
;     MMC1_UpdateROMBank
;     MMC1_UpdatePRGBankToStackA
;
; XREFS:
;     Sprites_PopulateNextAvailableSprite
;============================================================================
[c25b]Sprites_LoadSpriteValue:
[c25b]8aTXA; A = X (sprite index)
[c25c]a8TAY; Y = A


;
; Save the current ROM bank and switch to bank 11.
;
[c25d]ad 00 01LDA a:CurrentROMBank; Get the current ROM bank.
[c260]48PHA; Push to the stack.
[c261]a2 0bLDX #$0b; X = 11 (bank)
[c263]20 1a ccJSR MMC1_UpdateROMBank; Switch to bank 11.


;
; Restore our sprite index to X so it's not clobbered
; when this returns.
;
[c266]98TYA; A = Y
[c267]aaTAX; X = A


;
; Load the extra information for this sprite and store it
; in the sprite list.
;
[c268]a0 00LDY #$00; Y = 0
[c26a]b1 ccLDA (Screen_ExtraInfoAddr),Y; A = Extra information for the sprite.
[c26c]9d 6c 03STA a:CurrentSprites_Values,X; Store in CurrentSprites_Values.
[c26f]c9 ffCMP #$ff; Is it 0xFF (unset)?
[c271]f0 06BEQ @_restoreBankAndReturn; If so, we're done. Jump.


;
; Increment the position in the info data.
;
[c273]e6 ccINC Screen_ExtraInfoAddr; Increment the lower byte of the offset in the extra info data.
[c275]d0 02BNE @_restoreBankAndReturn; If this didn't wrap to 0, we're done. Jump.
[c277]e6 cdINC Screen_ExtraInfoAddr_U; Else, increment the upper byte as well.

[c279]@_restoreBankAndReturn:
[c279]4c d6 f3JMP MMC1_UpdatePRGBankToStackA; Restore the bank saved to the stack.

;============================================================================
; Determine and store the bank for images for the current sprite.
;
; This will determine which bank would store images for the
; currently-processed sprite.
;
; If the sprite entity ID is 0-54, this will be bank 6.
;
; If the sprite entity ID is 55-100, this will be bank 7.
;
; INPUTS:
;     CurrentSprite_Entity:
;         The entity ID for the currently-processed sprite.
;
;     SPRITE_IMAGE_BANKS:
;         The lookup table for sprite entity IDs to banks.
;
; OUTPUTS:
;     CurrentSprite_TilesBank:
;         The bank for the images for this sprite.
;
; XREFS:
;     GameLoop_LoadSpriteImages
;============================================================================
[c27c]Sprites_StoreBankForCurrentSprite:
[c27c]a0 00LDY #$00; Y = 0
[c27e]ad 8b 03LDA a:CurrentSprite_Entity; A = current sprite entity
[c281]c9 37CMP #$37; Is it < sprite 55 (Unused Child sprite)?
[c283]90 01BCC @_loadBank; If yes, then load bank from table at index 0.
[c285]c8INY; Else, load bank from table at index 1.


;
; Load the image for the bank.
;
[c286]@_loadBank:
[c286]b9 59 c2LDA a:SPRITE_IMAGE_BANKS,Y; Load the address for the sprite entity.
[c289]8d 86 03STA a:CurrentSprite_TilesBank; Store as the bank for this sprite.

[c28c]@_return:
[c28c]60RTS

;============================================================================
; Load images for all sprites on the scren.
;
; This will loop through each sprite and load the images,
; drawing them in the PPU buffer.
;
; If any sprites become off-screen (vertically), they'll be
; removed.
;
; As a special case, if the sprite is the boss Pakukame, a
; Lilith will be spawned.
;
; INPUTS:
;     CurrentSpriteIndex:
;         The current sprite index at the start of this
;         call.
;
;     CurrentSprites_Entities:
;         The list of sprite entities for all sprites on
;         screen.
;
; OUTPUTS:
;     CurrentSprites_Entities:
;         Updated if sprites are removed or added.
;
;     CurrentSprites_PPUOffsets:
;         PPU tile offsets for sprite data.
;
;     CurrentSprite_Entity:
;         Clobbered.
;
; CALLS:
;     CurrentSprite_ResetPPUTileOffset
;     PPUBuffer_WaitUntilClear
;     Sprites_LoadImageForCurrentSprite
;     Sprites_StoreBankForCurrentSprite
;
; XREFS:
;     Game_MainLoop
;     Game_SetupAndLoadOutsideArea
;     Game_SetupEnterBuilding
;     Game_SetupEnterScreen
;     Game_SetupExitBuilding
;     Game_SetupNewArea
;     Game_Start
;     IScripts_ClearPortraitImage
;============================================================================
[c28d]GameLoop_LoadSpriteImages:
;
; Save state and prepare for image loading.
;
[c28d]ad 78 03LDA a:CurrentSpriteIndex; A = current sprite index
[c290]48PHA; Push it to the stack.
[c291]20 6f cdJSR CurrentSprite_ResetPPUTileOffset; Reset the PPU drawing coordinates.


;
; Begin our loop for all 7 sprite slots.
;
[c294]a2 07LDX #$07; X = 7 (sprite index counter)


;
; Set this as the currently-processed sprite, and update
; the entity.
;
; We'll only process if the entity is not unset.
;
[c296]@_loop:
[c296]8e 78 03STX a:CurrentSpriteIndex; Store it as the currently-processed sprite index.
[c299]bd cc 02LDA a:CurrentSprites_Entities,X; Load the associated sprite entity ID.
[c29c]c9 ffCMP #$ff; Is it 0xFF (unset)?
[c29e]f0 3cBEQ @_nextLoop; If so, jump and prepare for the next loop.
[c2a0]8d 8b 03STA a:CurrentSprite_Entity; Store this as the entity at this index.


;
; Load the image for this sprite.
;
[c2a3]20 7c c2JSR Sprites_StoreBankForCurrentSprite; Store the image bank for the current sprite.
[c2a6]20 b5 cdJSR Sprites_LoadImageForCurrentSprite; Load the sprite's image from the bank.


;
; Special-case the Pakukame boss. If that was placed, then
; replace it with a Lilith instead. They spawn Liliths.
;
[c2a9]ad 8b 03LDA a:CurrentSprite_Entity; Load the current entity.
[c2ac]c9 30CMP #$30; Is it the Pakukame boss?
[c2ae]d0 19BNE @_loadSpriteInfo; If not, jump.


;
; This is the Pakukame. Swap in a Lilith and load the image.
;
; This will then restore the entity back to Pakukame.
; Effectively, each Lilith on screen seems to be backed by
; a Pakukame.
;
[c2b0]ad 8b 03LDA a:CurrentSprite_Entity; Load the Pakukame entity ID
[c2b3]48PHA; Push to the stack.
[c2b4]a5 9aLDA CurrentSprite_StartPPUTileOffset; Load the sprite's starting PPU tile offset.
[c2b6]48PHA; Push it to the stack.
[c2b7]a9 09LDA #$09; A = 9 (Lilith)
[c2b9]8d 8b 03STA a:CurrentSprite_Entity; Store as the new entity.
[c2bc]20 7c c2JSR Sprites_StoreBankForCurrentSprite; Store the bank for Lilith.
[c2bf]20 b5 cdJSR Sprites_LoadImageForCurrentSprite; Load Lilth's image from the bank.
[c2c2]68PLA; Pop the PPU offset row.
[c2c3]85 9aSTA CurrentSprite_StartPPUTileOffset; Store it again.
[c2c5]68PLA; Pop the current sprite entity.
[c2c6]8d 8b 03STA a:CurrentSprite_Entity; Store it again.


;
; Store the starting PPU tile offset for the sprite.
;
; This will be stored in this sprite's slot in the current
; sprites information.
;
[c2c9]@_loadSpriteInfo:
[c2c9]ae 78 03LDX a:CurrentSpriteIndex; X = current sprite index
[c2cc]a5 9aLDA CurrentSprite_StartPPUTileOffset; A = Start PPU tile offset
[c2ce]9d 2c 03STA a:CurrentSprites_PPUOffsets,X; Set this in the PPU tile offsets for this sprite.


;
; Check if the sprite is on-screen or off-screen.
;
; If the Y position is off the screen (row 30 or higher),
; then the sprite will be unset.
;
[c2d1]b5 c2LDA CurrentSprites_YPos,X; Load the Y position for this sprite.
[c2d3]c9 f0CMP #$f0; Is it less than 0xF0?
[c2d5]90 05BCC @_nextLoop; If so, loop.


;
; It's off-screen. Unset it.
;
[c2d7]a9 ffLDA #$ff; Else, it's off the screen.
[c2d9]9d cc 02STA a:CurrentSprites_Entities,X; Unset the entity.


;
; Done with any loading required for the sprite. Prepare for
; the next loop, if needed.
;
[c2dc]@_nextLoop:
[c2dc]ae 78 03LDX a:CurrentSpriteIndex; X = current sprite index (loop counter).
[c2df]caDEX; X--
[c2e0]10 b4BPL @_loop; If X >= 0, loop.


;
; We're done. Restore the original current sprite index and
; wait until everything's drawn to the screen.
;
[c2e2]68PLA; Pull A (current sprite index) from the stack.
[c2e3]8d 78 03STA a:CurrentSpriteIndex; Store that back as the current sprite index.
[c2e6]4c f4 cfJMP PPUBuffer_WaitUntilClear; Wait until everything's drawn to the screen.

;============================================================================
; Update a magic spell and run a magic-dependent handler.
;
; This is called for every tick of a magic spell. It's put
; on the stack by CastMagic_RunSpellHandler.
;
; This will update the visibility of the magic, set
; X/Y positions factoring in the screen scroll, and
; then set some state that ultimately is not used by
; the production build of Faxanadu.
;
; It will then call a magic-dependent update handler.
;
; INPUTS:
;     CastMagic_Type:
;         The magic type that was cast.
;
;     CastMagic_XPos_Full:
;         The X position of the magic.
;
;     CastMagic_YPos_Full:
;         The Y position of the magic.
;
;     Screen_Maybe_ScrollXCounter:
;     Player_Something_ScrollPosY:
;         Referenced but ultimately unused.
;
; OUTPUTS:
;     Arg_DrawSprite_PosX:
;     Arg_DrawSprite_PosY:
;         X and Y coordinates for the magic, used
;         for appearance management.
;
;     Unused_Sprite_ScrollPosX:
;     Unused_Sprite_ScrollPosY:
;         Set but unused.
;
; CALLS:
;     CastMagic_CalculateVisibility
;============================================================================
[c2e9]CastMagic_RunUpdateSpellHandler:
;
; These two lines are deadcode. It might be the developers
; attempting to hard-code Deluge and Thunder during testing?
; Each gets overriden immediately.
;
[c2e9]a9 00LDA #$00; A = 0 (deadcode)
[c2eb]a9 01LDA #$01; A = 1 (deadcode)
[c2ed]ad b3 02LDA a:CastMagic_Type; A = Cast magic type


;
; If 0xFF, return.
;
[c2f0]30 22BMI @_return


;
; This was an active, cast magic spell. Set state.
;
[c2f2]20 15 c3JSR CastMagic_CalculateVisibility; Calculate visibility for the magic spell based on foreground elements.


;
; Manage the X position of the spell.
;
[c2f5]ad b6 02LDA a:CastMagic_XPos_Full; Load the magic's X position.
[c2f8]85 27STA Arg_DrawSprite_PosX; Set as an argument for future appearance updates.


;
; Set some unused state not used in the finished game.
;
[c2fa]a5 9fLDA Screen_Maybe_ScrollXCounter
[c2fc]85 2bSTA Unused_Sprite_ScrollPosX


;
; Manage the Y position of the spell.
;
[c2fe]ad b8 02LDA a:CastMagic_YPos_Full
[c301]85 28STA Arg_DrawSprite_PosY; Set as an argument for future appearance updates.


;
; Set more unused state not used in the finished game.
;
[c303]a5 a2LDA Player_Something_ScrollPosY
[c305]85 2aSTA Unused_Sprite_ScrollPosY


;
; Set the finish handler for this type as the next function
; to run.
;
[c307]ad b3 02LDA a:CastMagic_Type; Load the magic type.
[c30a]0aASL A; Convert to a word boundary for the lookup table.
[c30b]a8TAY; Y = A
[c30c]b9 28 bbLDA a:CAST_MAGIC_UPDATE_FINISH_HANDLERS+1,Y; Load the lower byte of the finish handler.
[c30f]48PHA; Push to the stack.
[c310]b9 27 bbLDA a:CAST_MAGIC_UPDATE_FINISH_HANDLERS,Y; Load the upper byte.
[c313]48PHA; Push.

[c314]@_return:
[c314]60RTS; Return and then call the function.

;============================================================================
; Calculate the visibility of the cast magic.
;
; This will check the cast magic against any foreground
; blocks, checking if it's fully visible, partially
; obscured, or fully obscured.
;
; INPUTS:
;     CastMagic_XPos_Full:
;         The X pixel position of the magic.
;
;     CastMagic_YPos_Full:
;         The Y pixel position of the magic.
;
; OUTPUTS:
;     Temp_MovingSpriteVisibility:
;         The visibility state of the cast magic.
;
;     MovingSpriteVisibility:
;         The visibility state of the cast magic.
;
;     Arg_PixelPosX:
;     Arg_PixelPosX:
;         Clobbered.
;
; CALLS:
;     Area_ConvertPixelsToBlockPos
;     ScreenBuffer_LoadBlockProperty
;
; XREFS:
;     CastMagic_RunUpdateSpellHandler
;============================================================================
[c315]CastMagic_CalculateVisibility:
;
; Set the default to visible.
;
[c315]a9 00LDA #$00
[c317]85 b8STA Temp_MovingSpriteVisibility; Set the default visibility to visible.


;
; Convert the cast magic's position to block positions.
;
[c319]ad b8 02LDA a:CastMagic_YPos_Full; Load the magic's Y position.
[c31c]85 b6STA Arg_PixelPosY; Set it as an argument for getting the block property.
[c31e]ad b6 02LDA a:CastMagic_XPos_Full; Load the magic's X position.
[c321]18CLC
[c322]69 04ADC #$04; Add 4 to that to better check block alignment.
[c324]85 b5STA Arg_PixelPosX; Set it as an argument.
[c326]20 6c e8JSR Area_ConvertPixelsToBlockPos; Convert to a block position.
[c329]20 c3 e8JSR ScreenBuffer_LoadBlockProperty; Get the block property for this position.


;
; Check if a block overlaps the left.
;
[c32c]c9 04CMP #$04; Is this block type 4?
[c32e]f0 08BEQ @_leftIsObscured; If so, the left is obscured.
[c330]c9 0dCMP #$0d; Else, is this block type 13?
[c332]f0 04BEQ @_leftIsObscured; If so, the left is obscured.
[c334]c9 09CMP #$09; Else, is this block type 9?
[c336]d0 06BNE @_checkRightObscured; If not, the left is not obscured. Start checking the right.


;
; This is a foreground layer block. The trailing part
; is obscured.
;
[c338]@_leftIsObscured:
[c338]a5 b8LDA Temp_MovingSpriteVisibility; Load the cast magic's visibility state.
[c33a]09 01ORA #$01; Mark the left-hand side as obscured.
[c33c]85 b8STA Temp_MovingSpriteVisibility; Store it.


;
; Now check the right-hand side of the magic.
;
[c33e]@_checkRightObscured:
[c33e]a5 b5LDA Arg_PixelPosX; Load the pixel X position.
[c340]18CLC
[c341]69 08ADC #$08; Add 8 to it, to better check the right side.
[c343]85 b5STA Arg_PixelPosX; Store as the new pixel argument.
[c345]20 6c e8JSR Area_ConvertPixelsToBlockPos; Convert to a block position.
[c348]20 c3 e8JSR ScreenBuffer_LoadBlockProperty; Load the block property.


;
; Check if a block overlaps the right.
;
[c34b]c9 04CMP #$04; Is this block 4?
[c34d]d0 12BNE @_checkNeedToFlipBits; If not, it's not obscured.
[c34f]c9 04CMP #$04; Again, is this block 4?
[c351]f0 08BEQ @_rightIsObscured; If so, the right is obscured.
[c353]c9 0dCMP #$0d; Else, is this block 13?
[c355]f0 04BEQ @_rightIsObscured; If so, the right is obscured.
[c357]c9 09CMP #$09; Else, is this block 9?
[c359]d0 06BNE @_checkNeedToFlipBits; If not, it's not obscured. Move to the next step.


;
; The trailing side of the magic is obscured.
;
[c35b]@_rightIsObscured:
[c35b]a5 b8LDA Temp_MovingSpriteVisibility; Load the cast magic's visibility state.
[c35d]09 02ORA #$02; Mark the right-hand side as obscured.
[c35f]85 b8STA Temp_MovingSpriteVisibility; Store it.


;
; Check if the magic is partially-obscured (just left or
; right). If so, make sure the flips are flipped for the
; facing direction.
;
[c361]@_checkNeedToFlipBits:
[c361]ae 78 03LDX a:CurrentSpriteIndex; X = current sprite index.
[c364]ad b4 02LDA a:CastMagic_Flags; A = cast magic flags.
[c367]29 40AND #$40; Is it facing right?
[c369]f0 0dBEQ @_facingRight; If so, there's nothing to do. We're done.
[c36b]a5 b8LDA Temp_MovingSpriteVisibility; A = cast magic visibility
[c36d]f0 0bBEQ @_storeVisibility; If the block is fully visible, jump.
[c36f]c9 03CMP #$03; Else, is it full obscured?
[c371]f0 07BEQ @_storeVisibility; If yes, jump.


;
; Swap the bits to face the other direction.
;
[c373]49 03EOR #$03; Swap the visibility of leading and trailing flags.
[c375]4c 7a c3JMP @_storeVisibility; Jump to store.

[c378]@_facingRight:
[c378]a5 b8LDA Temp_MovingSpriteVisibility; Load the previously-calculated visibility from above.

[c37a]@_storeVisibility:
[c37a]85 26STA MovingSpriteVisibility; Store the new visibility state.
[c37c]60RTS

;============================================================================
; Set the appearance of the magic sprite.
;
; This will take in an offset into the magic's list of
; frames and set that as the new appearance.
;
; INPUTS:
;     A:
;         The offset into the list of frames.
;
;     CastMagic_Type:
;         The type of cast magic.
;
;     SPRITE_MAGIC_IMAGE_ADDRS_U:
;         The lookup table of upper addresses of magic
;         sprite images.
;
; CALLS:
;     Sprite_SetAppearanceAddrFromOffset
;
; XREFS:
;     CastMagic_FinishHandler_Death
;     CastMagic_FinishHandler_Deluge
;     CastMagic_FinishHandler_DelugeOrDeathAfterHit
;     CastMagic_FinishHandler_Fire
;     CastMagic_FinishHandler_HitWallEffect
;     CastMagic_FinishHandler_Thunder
;     CastMagic_FinishHandler_Tilte
;     CastMagic_FinishHandler_TilteAfterFirstHit
;============================================================================
[c37d]CastMagic_SetAppearance:
[c37d]ac b3 02LDY a:CastMagic_Type; Y = cast magic type
[c380]18CLC
[c381]79 87 c3ADC a:SPRITE_MAGIC_IMAGE_ADDRS_U,Y; Add the value from the lookup table.
[c384]4c 57 f0JMP Sprite_SetAppearanceAddrFromOffset; Set the sprite appearance.


;============================================================================
; Table of upper address bytes for magic sprite images.
;
; XREFS:
;     CastMagic_SetAppearance
;============================================================================

;
; XREFS:
;     CastMagic_SetAppearance
;
[c387]SPRITE_MAGIC_IMAGE_ADDRS_U:
[c387]95.byte $95; [0]: Deluge
[c388]99.byte $99; [1]: Thunder
[c389]9b.byte $9b; [2]: Fire
[c38a]9d.byte $9d; [3]: Death
[c38b]a1.byte $a1; [4]: Tilte
[c38c]a5.byte $a5; [5]: UNUSED: Deluge after first hit
[c38d]99.byte $99; [6]: Thunder after first hit
[c38e]9b.byte $9b; [7]: Fire after first hit
[c38f]a5.byte $a5; [8]: UNUSED: Death after first hit
[c390]a5.byte $a5; [9]: UNUSED
[c391]a5.byte $a5; [10]: UNUSED: Hit wall effect
[c392]a5.byte $a5; [11]: Tilte after first hit

;============================================================================
; Set whether a cast magic's sprite is flipped based on the cast direction.
;
; INPUTS:
;     CastMagic_Flags:
;         The cast magic's flags.
;
; OUTPUTS:
;     CurrentSprite_FlipMask:
;         The sprite's flip state.
;
; XREFS:
;     CastMagic_FinishHandler_Death
;     CastMagic_FinishHandler_Deluge
;     CastMagic_FinishHandler_DelugeOrDeathAfterHit
;     CastMagic_FinishHandler_Fire
;     CastMagic_FinishHandler_Thunder
;     CastMagic_FinishHandler_Tilte
;============================================================================
[c393]CastMagic_UpdateSpriteDirection:
[c393]ad b4 02LDA a:CastMagic_Flags; Load the cast magic's flags.
[c396]29 40AND #$40; Take only the facing direction bit.
[c398]85 29STA CurrentSprite_FlipMask; Set as the sprite's flip mask.
[c39a]60RTS

;============================================================================
; Finish updating the Deluge spell.
;
; This will maintain the sprite's direction and update
; the appearance.
;
; INPUTS:
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_UpdateSpriteDirection
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb27]
;============================================================================
[c39b]CastMagic_FinishHandler_Deluge:
[c39b]20 93 c3JSR CastMagic_UpdateSpriteDirection; Set the sprite's direction.
[c39e]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3a0]4aLSR A; Shift the interrupt counter to generate an appearance index.
[c3a1]4aLSR A
[c3a2]29 03AND #$03; Keep the 2 right-most bits (effectively, bits 3 and 4 of the interrupt counter).
[c3a4]4c 7d c3JMP CastMagic_SetAppearance; Set that as the appearance index.

;============================================================================
; Finish updating the Thunder spell.
;
; This will maintain the sprite's direction and update
; the appearance.
;
; It will update the appearance for 2 frames at a time,
; and wait 2 frames in-between.
;
; INPUTS:
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_UpdateSpriteDirection
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb29]
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb33]
;============================================================================
[c3a7]CastMagic_FinishHandler_Thunder:
[c3a7]20 93 c3JSR CastMagic_UpdateSpriteDirection; Set the sprite's direction.
[c3aa]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3ac]4aLSR A; Shift the interrupt counter to generate a value to check against.
[c3ad]4aLSR A
[c3ae]b0 05BCS @_return; If this should not update the appearance, return.
[c3b0]29 01AND #$01; Keep the right-most bit (effectively, bit 2 of the interrupt counter).
[c3b2]4c 7d c3JMP CastMagic_SetAppearance; Set that as the appearance index.

[c3b5]@_return:
[c3b5]60RTS

;============================================================================
; Finish updating the Fire spell.
;
; This will maintain the sprite's direction and update
; the appearance.
;
; It will run for 2 frames, skip 2 frames, run for 2 frames,
; etc.
;
; INPUTS:
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_UpdateSpriteDirection
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb2b]
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb35]
;============================================================================
[c3b6]CastMagic_FinishHandler_Fire:
[c3b6]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3b8]29 02AND #$02; Is bit 1 set?
[c3ba]d0 01BNE @_updateFire; If so, jump to update.
[c3bc]60RTS

[c3bd]@_updateFire:
[c3bd]20 93 c3JSR CastMagic_UpdateSpriteDirection; Set the sprite's direction.
[c3c0]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3c2]4aLSR A; Shift the interrupt counter to generate an appearance index.
[c3c3]4aLSR A
[c3c4]29 01AND #$01; Keep the right-most bit (effectively, bit 2 of the interrupt counter).
[c3c6]4c 7d c3JMP CastMagic_SetAppearance; Set that as the appearance index.

;============================================================================
; Finish updating the Death spell.
;
; This will maintain the sprite's direction and update
; the appearance.
;
; INPUTS:
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_UpdateSpriteDirection
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb2d]
;============================================================================
[c3c9]CastMagic_FinishHandler_Death:
[c3c9]20 93 c3JSR CastMagic_UpdateSpriteDirection; Update the sprite's direction.
[c3cc]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3ce]4aLSR A; Shift the interrupt counter to generate an appearance index.
[c3cf]4aLSR A
[c3d0]4aLSR A
[c3d1]29 03AND #$03; Keep the 2 right-most bits (effectively, bits 3 and 4 of the interrupt counter).
[c3d3]4c 7d c3JMP CastMagic_SetAppearance; Set that as the appearance index.

;============================================================================
; Finish updating the Tilte spell.
;
; This will set the appearance to 0, 1, 2, or 3,
; based on the current phase of the magic spell and
; the interrupt counter.
;
; The appearance will be:
;
; * 0: Magic phase is even;
;      Interrupt counter has bit 3 set.
;
; * 1: Magic phase is even;
;      Interrupt counter does not have bit 3 set.
;
; * 2: Magic phase is odd;
;      Interrupt counter has bit 1 and 2 unset.
;
; * 3: Magic phase is odd;
;      Interrupt counter has bit 1 unset and 2 set.
;
; INPUTS:
;     CastMagic_Phase:
;         The phase of the magic spell.
;
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb2f]
;============================================================================
[c3d6]CastMagic_FinishHandler_Tilte:
[c3d6]20 93 c3JSR CastMagic_UpdateSpriteDirection; Update the sprite's direction.


;
; Check if the first bit of the magic's phase is 0 or 1.
;
[c3d9]ad ba 02LDA a:CastMagic_Phase; Load the magic's phase.
[c3dc]4aLSR A; Shift bit 0 into Carry.
[c3dd]b0 0dBCS @_phaseIs1; If it's set, jump.


;
; The magic phase is 0. Update the appearance.
;
; The appearance value will be 1 if the interrupt counter
; does not have bit 3 set.
;
[c3df]a0 00LDY #$00; Y = 0
[c3e1]a5 1aLDA InterruptCounter; A = interrupt counter
[c3e3]29 08AND #$08; Keep bit 3.
[c3e5]f0 01BEQ @_setAppearance1; If 0, jump to use 0 as the appearance value.
[c3e7]c8INY; Y++ (appearance value == 1)

[c3e8]@_setAppearance1:
[c3e8]98TYA; A = 0 or 1 (appearance value)
[c3e9]4c 7d c3JMP CastMagic_SetAppearance; Set the appearance of the magic.


;
; The magic phase is 1. Update the appearance if the
; interrupt counter has bit 1 unset.
;
[c3ec]@_phaseIs1:
[c3ec]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c3ee]4aLSR A; Divide by 2.
[c3ef]4aLSR A; And place in Carry.
[c3f0]90 01BCC @_setAppearance2; If 0, jump to update appearance.
[c3f2]60RTS


;
; The appearance will be updated based on the interrupt
; counter. It will be 3 if bit 2 is unset, or 4 if set.
;
[c3f3]@_setAppearance2:
[c3f3]29 01AND #$01; Keep bit 0.
[c3f5]18CLC
[c3f6]69 02ADC #$02; Add 2.
[c3f8]4c 7d c3JMP CastMagic_SetAppearance; Set the appearance of the magic.

;============================================================================
; UNUSED: Finish handling updates to Deluge and Death spells that have
; collided at least once.
;
; This would maintain the sprite's direction and appearance.
;
; It's never actually run, due to both these spells clearing
; immediately when colliding.
;
; INPUTS:
;     None.
;
; OUTPUTS:
;     None.
;
; CALLS:
;     CastMagic_SetAppearance
;     CastMagic_UpdateSpriteDirection
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb31]
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb37]
;============================================================================
[c3fb]CastMagic_FinishHandler_DelugeOrDeathAfterHit:
[c3fb]20 93 c3JSR CastMagic_UpdateSpriteDirection; Update the sprite direction.
[c3fe]a9 00LDA #$00
[c400]4c 7d c3JMP CastMagic_SetAppearance; Set the appearance to 0.

;============================================================================
; UNUSED: Add a Magic Hit Wall effect.
;
; This was meant to be used by the Deluge and Fire magic.
; Upon hitting a wall, it would briefly spawn two explosion
; sprites (using the diagonal Tilte sprite) up against the
; collided block, before disappearing.
;
; This may have been wired off because there appears to be
; a race condition in the Fire spell, where it may not
; always show.
;
; This can be reactivated using the following Game Genie
; codes:
;
; ZAVLOUNN
; ZEUUSUNN
;
; INPUTS:
;     CastMagic_Unused_HitWallDeltaPosY:
;         The delta Y position for the hit wall sprite.
;
;     CastMagic_YPos_Full:
;         The Y position of the magic sprite.
;
; OUTPUTS:
;     CurrentSprite_FlipMask:
;         Set to 0.
;
;     Arg_DrawSprite_PosY:
;     Temp_00:
;         Clobbered.
;
; CALLS:
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb3b]
;============================================================================
[c403]CastMagic_FinishHandler_HitWallEffect:
;
; Set the default flip mask of the sprite to 0 (face right).
;
[c403]a9 00LDA #$00
[c405]85 29STA CurrentSprite_FlipMask; Set flip mask to face right.


;
; Calculate a multiplier used to position the explosion
; sprites.
;
; This will be the delta Y position * 2.
;
[c407]ad bb 02LDA a:CastMagic_Unused_HitWallDeltaPosY; A = Delta Y position.
[c40a]0aASL A; A *= 2
[c40b]85 00STA Temp_00; Save it temporarily.


;
; Position and draw the top explosion sprite.
;
; This will be MagicY - (DeltaY * 2).
;
[c40d]ad b8 02LDA a:CastMagic_YPos_Full; A = Magic Y position.
[c410]38SEC
[c411]e5 00SBC Temp_00; A -= Effect delta Y position.
[c413]85 28STA Arg_DrawSprite_PosY; Set as the new sprite's Y position.
[c415]a9 02LDA #$02
[c417]20 7d c3JSR CastMagic_SetAppearance; Draw the top explosion sprite at that position.


;
; Position and draw the bottom explosion sprite.
;
; This will be MagicY + 16 + (DeltaY * 2).
;
[c41a]ad bb 02LDA a:CastMagic_Unused_HitWallDeltaPosY; A = Delta Y position.
[c41d]0aASL A; A *= 2
[c41e]18CLC
[c41f]69 10ADC #$10; A += 16
[c421]18CLC
[c422]6d b8 02ADC a:CastMagic_YPos_Full; A += Magic Y position.
[c425]85 28STA Arg_DrawSprite_PosY; Save it as the new sprite's Y position.
[c427]a9 03LDA #$03
[c429]4c 7d c3JMP CastMagic_SetAppearance; Draw the bottom explosion sprite at that position.

;============================================================================
; Draw the Tilte explosion sprites after hitting an enemy.
;
; There are 4 sprites for the explosion, each moving in a
; diagonal direction outward from the impact point.
;
; This is computed by looping through each of the sprites
; and then calculating new X and Y positions for each, plus
; the appropriate tile appearance offset. XOR masks are used
; to turn the magic counter into a positive or negative
; number (depending on which piece of the explosion this is)
; in order to move that part in the correct direction.
;
; INPUTS:
;     CastMagic_Counter:
;         The lifetime counter for the explosion.
;
;     CastMagic_XPos_Full:
;         The center X position for the explosion.
;
;     CastMagic_YPos_Full:
;         The center Y position for the explosion.
;
;     MAGICHITHANDLER_TILTE_X_XORS:
;         The XOR table for generating positive/negative X
;         deltas for each part of the explosion.
;
;     MAGICHITHANDLER_TILTE_Y_XORS:
;         The XOR table for generating positive/negative Y
;         deltas for each part of the explosion.
;
;     MAGICHITHANDLER_TILTE_APPEARANCE_OFFSETS:
;         The appearance offsets for each part of the
;         explosion.
;
; OUTPUTS:
;     Arg_DrawSprite_PosX:
;     Arg_DrawSprite_PosY:
;     Temp_00:
;         Clobbered.
;
; CALLS:
;     CastMagic_SetAppearance
;
; XREFS:
;     CAST_MAGIC_UPDATE_FINISH_HANDLERS [$PRG14::bb3d]
;============================================================================
[c42c]CastMagic_FinishHandler_TilteAfterFirstHit:
;
; Clear the flip mask for the sprite.
;
[c42c]a9 00LDA #$00; A = 0.
[c42e]85 29STA CurrentSprite_FlipMask; Set as the flip mask (cleared).


;
; Prepare our loop. This will loop 4 times (3 -> 0, inclusive),
; calculating X and Y positions and an appearance offset for the
; sprite based on CastMagic_Counter (which will go from 1
; through 15).
;
; The loop counter corresponds to the corner of the explosion
; being processed:
;
; 0 = Top-left
; 1 = Top-right
; 2 = Bottom-left
; 3 = Bottom-right
;
[c430]a2 03LDX #$03; X = 3 (loop counter).


;
; Begin calculating a distance from the center based on the
; counter value.
;
; This will multiply the counter by 2 and then calculate a
; positive or negative value for X based on which corner
; of the explosion is being processed.
;
[c432]@_loop:
[c432]ad b9 02LDA a:CastMagic_Counter; Load the magic counter.
[c435]0aASL A; Multiply by 2.
[c436]48PHA; Push the result to the stack.


;
; Calculate the X position of the sprite.
;
[c437]85 00STA Temp_00; And store it for temporary usage.
[c439]5d 6c c4EOR a:MAGICHITHANDLER_TILTE_X_XORS,X; XOR with the index in our lookup table based on the loop counter.
[c43c]10 04BPL @_calcFinalXPosition; If the result is a positive value, jump.
[c43e]85 00STA Temp_00; Else, store our XOR'd result in our temp variable.
[c440]e6 00INC Temp_00; And increment it.


;
; Add our calculated position to the current X position,
; producing a final result. This will be set as the
; destination for drawing.
;
[c442]@_calcFinalXPosition:
[c442]ad b6 02LDA a:CastMagic_XPos_Full; Load the block X position of the magic sprite.
[c445]18CLC
[c446]65 00ADC Temp_00; Add our temp value.
[c448]85 27STA Arg_DrawSprite_PosX; Set as the X position argument.


;
; Calculate the Y position of the sprite.
;
[c44a]68PLA; Pop the previously-calculated magic counter * 2 result.
[c44b]85 00STA Temp_00; Store it back in our temp variable.
[c44d]5d 70 c4EOR a:MAGICHITHANDLER_TILTE_Y_XORS,X; XOR with the index in our lookup table based on the loop counter.
[c450]10 04BPL @_calcFinalYPosition; If the result is a positive value, jump.
[c452]85 00STA Temp_00; Else, store our XOR'd result in our temp variable.
[c454]e6 00INC Temp_00; And increment it.

[c456]@_calcFinalYPosition:
[c456]ad b8 02LDA a:CastMagic_YPos_Full; Load the Y position of the magic sprite.
[c459]18CLC
[c45a]65 00ADC Temp_00; Add the temp variable.
[c45c]85 28STA Arg_DrawSprite_PosY; Store as the Y position argument.


;
; Calculate the sprite tile offset.
;
[c45e]8aTXA; A = loop counter value.
[c45f]48PHA; Push it to the stack.
[c460]bd 74 c4LDA a:MAGICHITHANDLER_TILTE_APPEARANCE_OFFSETS,X; Load the offset based on the counter.


;
; Draw the tile for this part of the explosion.
;
[c463]20 7d c3JSR CastMagic_SetAppearance; Set the appearance of the sprite.
[c466]68PLA; Pop our loop counter.
[c467]aaTAX; Assign back to X.
[c468]caDEX; Decrement the loop counter.
[c469]10 c7BPL @_loop; If >= 0, loop.
[c46b]60RTS


;============================================================================
; Table of XORs for creating X deltas for parts of the Tilte explosion.
;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;============================================================================

;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;
[c46c]MAGICHITHANDLER_TILTE_X_XORS:
[c46c]ff.byte $ff; [0]: Top-left
[c46d]00.byte $00; [1]: Top-right
[c46e]ff.byte $ff; [2]: Bottom-left
[c46f]00.byte $00; [3]: Bottom-right


;============================================================================
; Table of XORs for creating X deltas for parts of the Tilte explosion.
;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;============================================================================

;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;
[c470]MAGICHITHANDLER_TILTE_Y_XORS:
[c470]ff.byte $ff; [0]: Top-left
[c471]ff.byte $ff; [1]: Top-right
[c472]00.byte $00; [2]: Bottom-left
[c473]00.byte $00; [3]: Bottom-right


;============================================================================
; Table of appearance offsets for parts of the Tilte explosion.
;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;============================================================================

;
; XREFS:
;     CastMagic_FinishHandler_TilteAfterFirstHit
;
[c474]MAGICHITHANDLER_TILTE_APPEARANCE_OFFSETS:
[c474]00.byte $00; [0]: Top-left
[c475]02.byte $02; [1]: Top-right
[c476]01.byte $01; [2]: Bottom-left
[c477]03.byte $03; [3]: Bottom-right

;============================================================================
; Check whether the user wants to use the selected item.
;
; This will check if the player has both initiated an action
; to use the item and is in a position to use one.
;
; If these conditions are met, the action handler for the
; item will be invoked.
;
; INPUTS:
;     Player_Flags:
;         The player's current flags.
;
;     Joy1_ButtonMask:
;         The currently-held buttons.
;
;     Joy1_ChangedButtonMask:
;         The newly-pressed buttons.
;
;     SelectedItem:
;         The selected item.
;
; OUTPUTS:
;     None
;
; XREFS:
;     EndGame_MainLoop
;     Game_MainLoop
;============================================================================
[c478]GameLoop_CheckUseCurrentItem:
[c478]a5 a4LDA Player_Flags; Load the player's flags.


;
; Check if the player is in a state where they'd be allowed
; to use an item.
;
[c47a]29 05AND #$05
[c47c]d0 1eBNE GameLoop_UseItem_Return


;
; Check if the Down button has been pressed. If not, return.
;
[c47e]a5 16LDA Joy1_ButtonMask; Load the button mask.
[c480]29 04AND #$04; Check if the Down button is pressed.
[c482]f0 18BEQ GameLoop_UseItem_Return; If not, return.


;
; Check if the B button has been pressed. If not, return.
;
[c484]ad 19 00LDA a:Joy1_ChangedButtonMask; Load the changed button mask.
[c487]29 40AND #$40; Check if the B button is pressed.
[c489]f0 11BEQ GameLoop_UseItem_Return; If not, return.


;
; Down-B was pressed. The item can be used, if a valid one is
; selected. Figure out if there's a valid one first...
;
[c48b]ad c1 03LDA a:SelectedItem; Load the selected item.
[c48e]0aASL A; Multiply by 2 to get a word boundary for address lookup.
[c48f]a8TAY; Y = A
[c490]c0 22CPY #$22; Is it a valid item?
[c492]b0 08BCS GameLoop_UseItem_Return; If not, return.


;
; Look up this item in the jump table and run it.
;
[c494]b9 9e c4LDA a:USE_ITEM_JUMP_TABLE+1,Y; Load the lower byte of the item handler address.
[c497]48PHA; Push it.
[c498]b9 9d c4LDA a:USE_ITEM_JUMP_TABLE,Y; Load the upper byte.
[c49b]48PHA; Push it.

;
; XREFS:
;     GameLoop_CheckUseCurrentItem
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c49d]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c49f]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4a1]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4a3]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4a5]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4a7]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4a9]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4ab]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4ad]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4b1]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4b3]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4b5]
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4b9]
;
[c49c]GameLoop_UseItem_Return:
[c49c]60RTS


;============================================================================
; Handler functions for using specific items.
;
; XREFS:
;     GameLoop_CheckUseCurrentItem
;============================================================================

;
; XREFS:
;     GameLoop_CheckUseCurrentItem
;
[c49d]USE_ITEM_JUMP_TABLE:
[c49d]9b c4pointer GameLoop_UseItem_Return-1; [0]: Ring of Elf
[c49f]9b c4pointer GameLoop_UseItem_Return-1; [1]: Ring of Ruby
[c4a1]9b c4pointer GameLoop_UseItem_Return-1; [2]: Ring of Dworf
[c4a3]9b c4pointer GameLoop_UseItem_Return-1; [3]: Demon's Ring
[c4a5]9b c4pointer GameLoop_UseItem_Return-1; [4]: "A" Key
[c4a7]9b c4pointer GameLoop_UseItem_Return-1; [5]: "K" Key
[c4a9]9b c4pointer GameLoop_UseItem_Return-1; [6]: "Q" Key
[c4ab]9b c4pointer GameLoop_UseItem_Return-1; [7]: "J" Key
[c4ad]9b c4pointer GameLoop_UseItem_Return-1; [8]: "Jo" Key
[c4af]15 c6pointer Player_UseMattock-1; [9]: Mattock
[c4b1]9b c4pointer GameLoop_UseItem_Return-1; [10]: Magical Rod
[c4b3]9b c4pointer GameLoop_UseItem_Return-1; [11]: Crystal
[c4b5]9b c4pointer GameLoop_UseItem_Return-1; [12]: Lamp
[c4b7]c7 c5pointer Player_UseHourGlass-1; [13]: Hour Glass
[c4b9]9b c4pointer GameLoop_UseItem_Return-1; [14]: Book
[c4bb]78 c5pointer Player_UseWingBoots-1; [15]: Wing Boots
[c4bd]32 c5pointer Player_UseRedPotion-1; [16]: Red Potion

;============================================================================
; Clear the selected item.
;
; INPUTS:
;     None
;
; OUTPUTS:
;     SelectedItem:
;         The cleared item selection.
;
; CALLS:
;     UI_ClearSelectedItemPic
;
; XREFS:
;     Player_UseHourGlass
;     Player_UseMattock
;     Player_UseRedPotion
;     Player_UseWingBoots
;============================================================================
[c4bf]Player_ClearSelectedItem:
[c4bf]48PHA; Push A to the stack.
[c4c0]a9 ffLDA #$ff
[c4c2]8d c1 03STA a:SelectedItem; Set selected item to 0xFF (unset).
[c4c5]20 dc c8JSR UI_ClearSelectedItemPic; Update the UI for the cleared image.
[c4c8]68PLA; Pop A from the stack.
[c4c9]60RTS

;============================================================================
; Use the player's Elixir.
;
; This will remove the Elixir from the inventory and update the player's
; health.
;
; This then falls through to Player_FillHPAndMP.
;
; INPUTS:
;     SpecialItems:
;         The special items bitmask to update.
;
;     Player_HP_U:
;         The player's HP.
;
;     Player_MP:
;         The player's MP.
;
; OUTPUTS:
;     SpecialItems:
;         The new special items bitmask with the
;         Elixir removed.
;
;     Player_HP_U:
;         The player's updated HP.
;
;     Player_MP:
;         The player's updated MP.
;
; CALLS:
;     Player_AddHP
;     Player_AddMP
;     MMC1_LoadBankAndJump
;     Sound_PlayEffect
;     WaitForNextFrame
;     Sprites_FlipRanges
;
; XREFS:
;     Player_ReduceHP
;============================================================================
[c4ca]Player_UseElixir:
[c4ca]ad 2c 04LDA a:SpecialItems; Load the special items.
[c4cd]29 f7AND #$f7; Clear the elixir bit.
[c4cf]8d 2c 04STA a:SpecialItems; Store it.


;
; Run the "Use Elixir" IScript.
;
; IScript 0x85 via jump to IScripts_Begin.
;
[c4d2]a9 85LDA #$85; 0x85 == Use Elixir.
[c4d4]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c4d7]0c.byte BANK_12_LOGIC; Bank = 12
[c4d8]41 82pointer IScripts_Begin-1; Address = IScripts_Begin

;============================================================================
; Progressively fill the player's HP and MP.
;
; This will add 4HP and 4MP at a time, playing a sound
; effect for each segment. This appears to the player as
; the HP and MP bars filling up.
;
; INPUTS:
;     SpecialItems:
;         The special items bitmask to update.
;
;     Player_HP_U:
;         The player's HP.
;
;     Player_MP:
;         The player's MP.
;
; OUTPUTS:
;     SpecialItems:
;         The new special items bitmask with the
;         Elixir removed.
;
;     Player_HP_U:
;         The player's updated HP.
;
;     Player_MP:
;         The player's updated MP.
;
; CALLS:
;     Player_AddHP
;     Player_AddMP
;     MMC1_LoadBankAndJump
;     Sound_PlayEffect
;     WaitForNextFrame
;     Sprites_FlipRanges
;
; XREFS:
;     Player_FillHPAndMP
;============================================================================
[c4da]Player_FillHPAndMP:
;
; Progressively fill the HP, 4 units at a time.
;
; Start by playing the sound.
;
[c4da]a9 13LDA #$13; Set sound 0x13 (fill HP/MP bar).
[c4dc]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Add the HP.
;
[c4df]a9 04LDA #$04; Set the HP to 4 units.
[c4e1]20 7b c0JSR Player_AddHP; Add it to the player.
[c4e4]20 46 dcJSR Game_DrawScreenInFrozenState; Draw the screen, and prevent updating until done.


;
; Wait 4 frames of updates before filling up the next units
; of HP, to help animate the bar.
;
[c4e7]20 25 caJSR WaitForNextFrame; Wait a bit.
[c4ea]20 a8 cbJSR Sprites_FlipRanges
[c4ed]20 25 caJSR WaitForNextFrame
[c4f0]20 a8 cbJSR Sprites_FlipRanges
[c4f3]20 25 caJSR WaitForNextFrame
[c4f6]20 a8 cbJSR Sprites_FlipRanges
[c4f9]20 25 caJSR WaitForNextFrame
[c4fc]20 a8 cbJSR Sprites_FlipRanges


;
; Check if we're done filling up HP.
;
[c4ff]ad 31 04LDA a:Player_HP_U; Load the player's HP.
[c502]c9 50CMP #$50; Is it below the cap of 80HP?
[c504]90 d4BCC Player_FillHPAndMP; If so, loop.


;
; Progressively fill the MP, 4 units at a time.
;
; Start by playing the sound.
;
[c506]@_fillMPLoop:
[c506]a9 13LDA #$13; Set sound 0x13 (fill HP/MP bar).
[c508]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Add the MP.
;
[c50b]a9 04LDA #$04; Set the MP to 4 units.
[c50d]20 d9 c0JSR Player_AddMP; Add it to the player.
[c510]20 46 dcJSR Game_DrawScreenInFrozenState; Draw the screen but keep all sprites frozen.


;
; Wait 4 frames of updates before filling up the next units
; of MP, to help animate the bar.
;
[c513]20 25 caJSR WaitForNextFrame; Wait a bit.
[c516]20 a8 cbJSR Sprites_FlipRanges
[c519]20 25 caJSR WaitForNextFrame
[c51c]20 a8 cbJSR Sprites_FlipRanges
[c51f]20 25 caJSR WaitForNextFrame
[c522]20 a8 cbJSR Sprites_FlipRanges
[c525]20 25 caJSR WaitForNextFrame
[c528]20 a8 cbJSR Sprites_FlipRanges


;
; Check if we're done filling up MP.
;
[c52b]ad 9a 03LDA a:Player_MP; Load the player's MP.
[c52e]c9 50CMP #$50; Is it below the cap of 80MP?
[c530]90 d4BCC @_fillMPLoop; If so, loop.
[c532]60RTS

;============================================================================
; Use the Red Potion item.
;
; This will play the Red Potion message and a sound
; effect, and remove the item from the inventory.
;
; Health will be progressively filled.
;
; INPUTS:
;     Player_HP_U:
;         The player's HP.
;
; OUTPUTS:
;     Player_HP_U:
;         The player's updated HP.
;
; CALLS:
;     Game_DrawScreenInFrozenState
;     MMC1_LoadBankAndJump
;     Player_ClearSelectedItem
;     Player_AddHP
;     Sound_PlayEffect
;     Sprites_FlipRanges
;     WaitForNextFrame
;
; XREFS:
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4bd]
;============================================================================
[c533]Player_UseRedPotion:
;
; Run the "Used Red Potion" IScript.
;
; IScript 0x80 via jump to IScripts_Begin.
;
[c533]a9 80LDA #$80; 0x80 == Use Red Potion IScript.
[c535]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c538]0c.byte BANK_12_LOGIC; Bank = 12
[c539]41 82pointer IScripts_Begin-1; Address = IScripts_Begin

[c53b]@_afterFarJump:
[c53b]20 bf c4JSR Player_ClearSelectedItem; Clear the selected item.


;
; Play the initial sound effect.
;
[c53e]a9 1aLDA #$1a; 0x1A == Initial item used sound effect.
[c540]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Set up the HP fill loop. This will fill up to 80.
;
[c543]a2 50LDX #$50; X = Maximum HP / our loop counter.

[c545]@_loop:
[c545]8aTXA; A = X
[c546]48PHA; Push it to the stack.


;
; Play the unit fill sound effect.
;
[c547]a9 13LDA #$13; 0x13 = Unit of HP fill sound effect.
[c549]20 e4 d0JSR Sound_PlayEffect; Play the sound.


;
; Add 2HP.
;
[c54c]a9 02LDA #$02
[c54e]20 7b c0JSR Player_AddHP; Add the 2HP to the player.
[c551]20 46 dcJSR Game_DrawScreenInFrozenState


;
; Wait 4 frames worth of updates before filling the next 2HP.
;
[c554]20 25 caJSR WaitForNextFrame
[c557]20 a8 cbJSR Sprites_FlipRanges
[c55a]20 25 caJSR WaitForNextFrame
[c55d]20 a8 cbJSR Sprites_FlipRanges
[c560]20 25 caJSR WaitForNextFrame
[c563]20 a8 cbJSR Sprites_FlipRanges
[c566]20 25 caJSR WaitForNextFrame
[c569]20 a8 cbJSR Sprites_FlipRanges


;
; Check if we're done.
;
[c56c]68PLA; Pop the max HP.
[c56d]aaTAX; X = A
[c56e]ad 31 04LDA a:Player_HP_U; Load the player's current HP.
[c571]c9 50CMP #$50; Is the player at max HP?
[c573]b0 03BCS @_return; If so, return.
[c575]caDEX; X--
[c576]d0 cdBNE @_loop; If X > 0, loop.

[c578]@_return:
[c578]60RTS

;============================================================================
; Use the Wing Boots item.
;
; This will play the Wing Boots message and a sound
; effect, and remove the item from the inventory.
;
; The duration of the Wing Boots will depend on the
; player's title:
;
; * 40 seconds: Novice, Aspirant, Battler, Fighter
; * 30 seconds: Adept, Chevalier, Veteran, Warrior
; * 20 seconds: Swordman, Hero, Soldier, Myrmidon
; * 10 seconds: Champion, Superhero, Paladin, Lor
;
; INPUTS:
;     PlayerTitle:
;         The player's current title.
;
;     TITLE_TO_WINGBOOTS_DURATION:
;         The table of player titles to Wingboots duration.
;
; OUTPUTS:
;     DurationWingBoots:
;         The starting number of seconds remaining for the
;         Wing Boots.
;
; CALLS:
;     Player_ClearSelectedItem:
;     Sound_PlayEffect
;     MMC1_LoadBankAndJump
;     UI_DrawTimeValue
;
; XREFS:
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4bb]
;============================================================================
[c579]Player_UseWingBoots:
;
; Run the "Wing Boots Used" IScript.
;
; IScript 0x83 via jump to IScripts_Begin.
;
[c579]a9 83LDA #$83; 0x83 == Wing Boots used IScript.
[c57b]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c57e]0c.byte BANK_12_LOGIC; Bank = 12
[c57f]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Remove the item.
;
[c581]@_afterFarJump:
[c581]20 bf c4JSR Player_ClearSelectedItem; Clear the selected item.


;
; Play a sound effect for the item usage.
;
[c584]a9 1aLDA #$1a; Set the sound to play to 0x1A (special item sound).
[c586]20 e4 d0JSR Sound_PlayEffect; Play the sound.


;
; Calculate the index into the duration table based on
; the player's title.
;
[c589]ad 37 04LDA a:PlayerTitle; Load the player's title.
[c58c]4aLSR A; Divide by 4.
[c58d]4aLSR A
[c58e]aaTAX; X = A (index)
[c58f]bd 99 c5LDA a:TITLE_TO_WINGBOOTS_DURATION,X; Look up in the duration table.
[c592]8d 29 04STA a:DurationWingBoots; Set that as the starting duration.
[c595]20 90 f9JSR UI_DrawTimeValue; Draw the time on the HUD.
[c598]60RTS


;============================================================================
; Wing Boots durations by player title.
;
; The duration decreases every 4 player titles.
;
; XREFS:
;     Player_UseWingBoots
;============================================================================

;
; XREFS:
;     Player_UseWingBoots
;
[c599]TITLE_TO_WINGBOOTS_DURATION:
[c599]28.byte $28; [0]: 40 seconds: Novice, Aspirant, Battler, Fighter
[c59a]1e.byte $1e; [1]: 30 seconds: Adept, Chevalier, Veteran, Warrior
[c59b]14.byte $14; [2]: 20 seconds: Swordman, Hero, Soldier, Myrmidon
[c59c]0a.byte $0a; [3]: 10 seconds: Champion, Superhero, Paladin, Lord

;============================================================================
; Decrement the Wing Boot's duration.
;
; This will decrement and then draw the time in the HUD.
;
; INPUTS:
;     DurationWingBoots:
;         The remaining duration for the Wing Boots.
;
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     DurationWingBoots:
;         The new duration for the Wing Boots.
;
; CALLS:
;     MMC1_LoadBankAndJump
;     UI_DrawTimeValue
;
; XREFS:
;     GameLoop_CountdownItems
;============================================================================
[c59d]Game_DecWingBootsDuration:
;
; Check if there's any time remaining on the Wing Boots.
;
[c59d]ad 29 04LDA a:DurationWingBoots; Load the remaining time on the Wing Boots.
[c5a0]30 25BMI @_return; If the counter is unset (0xFF), return.


;
; Update the player's status to mark Wing Boots as on.
;
[c5a2]a5 a5LDA Player_StatusFlag; Load the player's status flags.
[c5a4]09 80ORA #$80; Enable the Wing Boots bit.
[c5a6]85 a5STA Player_StatusFlag; Store it.


;
; Update at most once every second.
;
[c5a8]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c5aa]29 3fAND #$3f; Check if we're at the 1 second mark.
[c5ac]d0 19BNE @_return; If not, return.


;
; Reduce time on the Wing Boots by a second.
;
[c5ae]ce 29 04DEC a:DurationWingBoots; Decrement the remaining time for the Wing Boots.
[c5b1]ad 29 04LDA a:DurationWingBoots; Load that duration
[c5b4]30 03BMI @_wingBootsDone; If it wrapped from 0 to 0xFF, it's used up. Jump.
[c5b6]4c 90 f9JMP UI_DrawTimeValue; Else, draw the time remaining.


;
; The Wing Boots ran out. Remove the flag from the player's
; status.
;
[c5b9]@_wingBootsDone:
[c5b9]a5 a5LDA Player_StatusFlag; Load the player's status flags.
[c5bb]29 7fAND #$7f; Clear the Wing Boots flag.
[c5bd]85 a5STA Player_StatusFlag; Store it.


;
; Run "Wing Boots are gone" IScript.
;
; IScript 0x96 via jump to IScripts_Begin.
;
[c5bf]a9 96LDA #$96; 0x96 == Wing Boots are gone IScript.
[c5c1]20 59 f8JSR MMC1_LoadBankAndJump; Run the IScript:
[c5c4]0c.byte BANK_12_LOGIC; Bank = 12
[c5c5]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; It will resume here.
;
[c5c7]@_return:
[c5c7]60RTS

;============================================================================
; Use the Hour Glass.
;
; This will invoke the IScript for the Hour Glass's
; message, play a sound, and begin the Hour Glass
; effect.
;
; The player's health will be reduced by half in the
; process.
;
; INPUTS:
;     Player_HP_U:
;     Player_HP_L:
;         The player's current health.
;
; OUTPUTS:
;     Player_HP_U:
;     Player_HP_L:
;         The player's new health, reduced by half.
;
;     DurationHourGlass:
;         The duration of the Hour Glass.
;
;     Music_Current:
;         The music to play while the Hour Glass is
;         active.
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Player_ClearSelectedItem
;     Sound_PlayEffect
;     UI_DrawPlayerHP
;
; XREFS:
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4b7]
;============================================================================
[c5c8]Player_UseHourGlass:
;
; Run the "Hour Glass Used" IScript.
;
; IScript 0x82 via jump to IScripts_Begin.
;
[c5c8]a9 82LDA #$82; Set the IScript to run to 0x82.
[c5ca]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c5cd]0c.byte BANK_12_LOGIC; Bank = 12
[c5ce]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Remove the item.
;
[c5d0]@_afterFarJump:
[c5d0]20 bf c4JSR Player_ClearSelectedItem; Clear the selected item.


;
; Play a sound effect for the item usage.
;
[c5d3]a9 1aLDA #$1a; Set the sound to play to 0x1A (special item sound).
[c5d5]20 e4 d0JSR Sound_PlayEffect; Play the sound.


;
; Reduce the player's health by half. This is the cost of
; the Hour Glass.
;
[c5d8]4e 31 04LSR a:Player_HP_U; Divide the upper value of the player's HP by half.
[c5db]6e 32 04ROR a:Player_HP_L; Divide the lower byte of the player's HP by half, and add carry from the upper.
[c5de]20 bd c0JSR UI_DrawPlayerHP; Draw the new HP.


;
; Set the duration of the Hour Glass to 15 seconds.
;
[c5e1]a9 0fLDA #$0f; Set the duration to 15 seconds.
[c5e3]8d 2a 04STA a:DurationHourGlass


;
; Change the music.
;
[c5e6]a9 0bLDA #$0b; Set the new music to play.
[c5e8]85 faSTA Music_Current; And play it.
[c5ea]60RTS

;============================================================================
; Decrement the Hour Glass's duration.
;
; INPUTS:
;     DurationHourGlass:
;         The remaining duration for the Hour Glass.
;
;     InterruptCounter:
;         The current interrupt counter.
;
; OUTPUTS:
;     DurationHourGlass:
;         The new duration for the Hour Glass..
;
;     Music_Current:
;         The restored music for the area.
;
; CALLS:
;     MMC1_LoadBankAndJump
;
; XREFS:
;     GameLoop_CountdownItems
;============================================================================
[c5eb]Game_DecHourGlassDuration:
;
; Check if there's any time remaining on the Hour Glass.
;
[c5eb]ad 2a 04LDA a:DurationHourGlass; Load the remaining time on the Hour Glass.
[c5ee]30 18BMI @_return; If the counter is unset (0xFF), return.


;
; Update at most once every second.
;
[c5f0]a5 1aLDA InterruptCounter; Load the interrupt counter.
[c5f2]29 3fAND #$3f; Check if we're at the 1 second mark.
[c5f4]d0 12BNE @_return; If not, return.


;
; Reduce time on the Hour Glass by a second.
;
[c5f6]ce 2a 04DEC a:DurationHourGlass; Decrement the remaining time for the Hour Glass.
[c5f9]10 0dBPL @_return; If it wrapped from 0 to 0xFF, it's used up. Jump.


;
; Run "Hour Glass is gone" IScript.
;
; IScript 0x97 via jump to IScripts_Begin.
;
[c5fb]a9 97LDA #$97; 0x97 == Hour Glass is gone IScript.
[c5fd]20 59 f8JSR MMC1_LoadBankAndJump; Run the IScript:
[c600]0c.byte BANK_12_LOGIC; Bank = 12
[c601]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Load the area's default music.
;
[c603]@_afterFarJump:
[c603]ad d1 03LDA a:Areas_DefaultMusic; Load the music for the area.
[c606]85 faSTA Music_Current; Store it.

[c608]@_return:
[c608]60RTS

;============================================================================
; Add 100XP to the player's experience.
;
; INPUTS:
;     None
;
; OUTPUTS:
;     Temp_Int24:
;     Temp_Int24+1:
;         Clobbered.
;
; CALLS:
;     Player_UpdateExperience
;
; XREFS:
;     Player_PickUpGlove
;     Player_PickUpOintment
;============================================================================
[c609]Player_Add100XP:
[c609]a9 64LDA #$64; A = 100 (lower byte of XP)
[c60b]8d ec 00STA a:Temp_Int24; Store it as an argument.
[c60e]a9 00LDA #$00; A = 0 (upper byte of XP).
[c610]8d ed 00STA a:Temp_Int24_M; Store it as an argument.
[c613]4c 57 f9JMP Player_UpdateExperience; Update the player's experience using those values.

;============================================================================
; Use the Mattock.
;
; This will check if the Mattock can be used at the current
; player position. If so, it will invoke the IScript for the
; Mattock's message, play a sound, and update the level state.
;
; INPUTS:
;     Area_CurrentArea:
;         The current area.
;
;     Player_PosX_Block:
;         The player's current X position.
;
;     Player_PosY:
;         The player's current Y position.
;
;     Player_Flags:
;         The player's flags.
;
;     USE_MATTOCK_BLOCK_DISTANCES:
;         TODO
;
; OUTPUTS:
;     Arg_PixelPosX:
;     Arg_PixelPosY:
;         Clobbered.
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Player_ClearSelectedItem
;     Sound_PlayEffect
;     WaitForNextFrame
;     Area_SetBlocks
;
; XREFS:
;     USE_ITEM_JUMP_TABLE [$PRG15_MIRROR::c4af]
;============================================================================
[c616]Player_UseMattock:
;
; Check if the block check position will be in bounds.
;
; The offset will be dependent on the facing direction.
;
; If facing left, this will check the block immediately
; to the left (0xFF -- wrapping around the screen).
;
; If facing right, this will check block + 16 (within or
; at the end of the blocks to clear).
;
[c616]a0 00LDY #$00; Lookup table index = 0 (default)
[c618]a5 a4LDA Player_Flags; Load the player's flags.
[c61a]29 40AND #$40; Is the player facing right?
[c61c]f0 01BEQ @LAB_PRG15_MIRROR__c61f; If not, jump.


;
; The player is facing right. Set our offset into the block
; distances table to 1.
;
[c61e]c8INY; Lookup table index = 1

[c61f]@LAB_PRG15_MIRROR__c61f:
[c61f]a5 9eLDA Player_PosX_Block; Get the player's X position.
[c621]18CLC
[c622]79 8d c6ADC a:USE_MATTOCK_BLOCK_DISTANCES,Y; Add the block distance for the facing direction.
[c625]c9 f0CMP #$f0; Is the player too near to the right edge of the screen?
[c627]b0 63BCS @_return; If so, return.


;
; Begin fetching the block at this offset.
;
; Same logic as above for block calculation.
;
[c629]85 b5STA Arg_PixelPosX; Store the calculated position as the X argument.
[c62b]a5 a1LDA Player_PosY; Load the player's current Y position.
[c62d]85 b6STA Arg_PixelPosY; Store that as the Y argument.
[c62f]20 6c e8JSR Area_ConvertPixelsToBlockPos; Convert those pixel positions to block positions.


;
; Check if the screen buffer contains the blocks to clear.
; If not, there's nothing to do.
;
; Each block is composed of 4 tiles, which are represented
; in the lookup table. This only needs to check for the
; presence of one of those blocks.
;
[c632]a5 24LDA Area_CurrentArea; Load the current area.
[c634]0aASL A; Convert to a 4 byte index.
[c635]0aASL A
[c636]a8TAY; Y = index
[c637]bd 00 06LDA a:ScreenBuffer,X; Load the value from the screen buffer.
[c63a]d9 8f c6CMP a:USE_MATTOCK_BLOCK_TRANSITIONS,Y; Is this block already cleared by the Mattock?
[c63d]f0 01BEQ @_useMattock; If not, use the Mattock to clear them.
[c63f]60RTS; Else, return.


;
; The Mattock will be used. Store the offsets into the
; screen buffer and array on the stack for later.
;
[c640]@_useMattock:
[c640]8aTXA; A = X
[c641]48PHA; Push to the stack.
[c642]98TYA; A = Y
[c643]48PHA; Push to the stack.


;
; Run the "Used Mattock" IScript.
;
; IScript 0x81 via jump to IScripts_Begin.
;
[c644]a9 81LDA #$81
[c646]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c649]0c.byte BANK_12_LOGIC; Bank = 12
[c64a]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Remove the Mattock.
;
[c64c]@_afterFarJump:
[c64c]20 bf c4JSR Player_ClearSelectedItem; Clear the selected item.


;
; Play the sound effect for the Mattock usage.
;
[c64f]a9 1aLDA #$1a; 0x1A == Special item sound effect.
[c651]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Prepare for the loop.
;
; This loop will handle animating the destruction/crumbling
; of blocks. This uses 4 frames of animation, all defined in
; USE_MATTOCK_BLOCK_TRANSITIONS.
;
[c654]68PLA; Pull A from the stack.
[c655]a8TAY; Y = A
[c656]68PLA; Pull A from the stack.
[c657]aaTAX; X = A


;
; Only update every 4 frames, to get a quick animation effect.
;
[c658]@_loop:
[c658]20 25 caJSR WaitForNextFrame; Wait for 4 frames.
[c65b]20 25 caJSR WaitForNextFrame
[c65e]20 25 caJSR WaitForNextFrame
[c661]20 25 caJSR WaitForNextFrame


;
; Update the screen to place the next block in the sequence.
;
[c664]98TYA; A = Y
[c665]48PHA; Push to the stack.
[c666]8aTXA; A = X
[c667]48PHA; Push to the stack.
[c668]b9 8f c6LDA a:USE_MATTOCK_BLOCK_TRANSITIONS,Y; Load the block for this position.
[c66b]9d 00 06STA a:ScreenBuffer,X; And store it in the screen buffer.
[c66e]20 c5 d7JSR Area_SetBlocks; Update the level data.


;
; Update to the next block.
;
[c671]8aTXA; A = X
[c672]18CLC
[c673]69 10ADC #$10; A += 32
[c675]aaTAX; X = A
[c676]ad c9 03LDA a:Arg_BlockAttributesIndex; Load a value.
[c679]9d 00 06STA a:ScreenBuffer,X; And write it to the screen buffer.
[c67c]20 c5 d7JSR Area_SetBlocks; Upate the level data.


;
; Prepare for the next loop iteration.
;
[c67f]68PLA; Pull A from the stack.
[c680]aaTAX; X = A
[c681]68PLA; Pull A from the stack.
[c682]a8TAY; Y = A
[c683]c8INY; Y++
[c684]98TYA; A = Y
[c685]29 03AND #$03; Have we finished updating the blocks?
[c687]f0 03BEQ @_return; If so, return.
[c689]4c 58 c6JMP @_loop; Else, loop.

[c68c]@_return:
[c68c]60RTS


;============================================================================
; Block distances for checking if a player is on-screen.
;
; This is used when using the Mattock.
;
; XREFS:
;     Player_UseMattock
;============================================================================

;
; XREFS:
;     Player_UseMattock
;
[c68d]USE_MATTOCK_BLOCK_DISTANCES:
[c68d]ff.byte $ff; [0]:

;
; XREFS:
;     Player_UseMattock
;
[c68e]USE_MATTOCK_BLOCK_DISTANCES_1_:
[c68e]10.byte $10; [1]:


;============================================================================
; New block IDs to place when clearing blocks.
;
; This is divided into regions, each with 4 blocks.
; Those 4 blocks are an animation transition between
; the placed blocks (index 0 within a group) and
; cleared blocks (index 3).
;
; XREFS:
;     Player_UseMattock
;============================================================================

;
; XREFS:
;     Player_UseMattock
;
[c68f]USE_MATTOCK_BLOCK_TRANSITIONS:
[c68f]00.byte $00; [0]: Eolis
[c690]00.byte $00; [1]:
[c691]00.byte $00; [2]:
[c692]00.byte $00; [3]:
[c693]63.byte $63; [4]: Apolune
[c694]85.byte $85; [5]:
[c695]86.byte $86; [6]:
[c696]42.byte $42; [7]:
[c697]00.byte $00; [8]: Forepaw
[c698]00.byte $00; [9]:
[c699]00.byte $00; [10]:
[c69a]00.byte $00; [11]:
[c69b]00.byte $00; [12]: Mascon
[c69c]00.byte $00; [13]:
[c69d]00.byte $00; [14]:
[c69e]00.byte $00; [15]:
[c69f]00.byte $00; [16]: Victim
[c6a0]00.byte $00; [17]:
[c6a1]00.byte $00; [18]:
[c6a2]00.byte $00; [19]:
[c6a3]00.byte $00; [20]: Conflate
[c6a4]00.byte $00; [21]:
[c6a5]00.byte $00; [22]:
[c6a6]00.byte $00; [23]:
[c6a7]00.byte $00; [24]: Daybreak
[c6a8]00.byte $00; [25]:
[c6a9]00.byte $00; [26]:
[c6aa]00.byte $00; [27]:
[c6ab]00.byte $00; [28]: Evil Fortress
[c6ac]00.byte $00; [29]:
[c6ad]00.byte $00; [30]:
[c6ae]00.byte $00; [31]:

;============================================================================
; Clear timers on all temporary status items.
;
; This applies to the Glove, Ointment, Wing Boots, and
; Hour Glass.
;
; INPUTS:
;     None
;
; OUTPUTS:
;     DurationGlove:
;     DurationHourGlass:
;     DurationOintment:
;     DurationWingBoots:
;         All set to 0xFF (not active).
;
; XREFS:
;     Game_Start
;     Player_Spawn
;============================================================================
[c6af]Game_ClearTimedItems:
[c6af]a9 ffLDA #$ff
[c6b1]8d 28 04STA a:DurationGlove; Clear the Glove duration.
[c6b4]8d 27 04STA a:DurationOintment; Clear the Ointment duration.
[c6b7]8d 29 04STA a:DurationWingBoots; Clear the Wing Boots duration.
[c6ba]8d 2a 04STA a:DurationHourGlass; Clear the Hour Glass duration.
[c6bd]60RTS

;============================================================================
; Handle picking up the Hour Glass.
;
; This will invoke the IScript, play the sound, and add
; the Hour Glass to the inventory.
;
; INPUTS:
;     None
;
; OUTPUTS:
;     None
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Sound_PlayEffect
;     Player_PickUpItem
;
; XREFS:
;     Player_PickUp
;============================================================================
[c6be]Player_PickUpHourGlass:
;
; Run the "Got Hour Glass" IScript.
;
; IScript 0x8A via jump to IScripts_Begin.
;
[c6be]a9 8aLDA #$8a; 0x8A == Hour Glass picked up IScript.
[c6c0]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c6c3]0c.byte BANK_12_LOGIC; Bank = 12
[c6c4]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Play the sound effect for picking up an item.
;
[c6c6]@_afterFarJump:
[c6c6]a9 08LDA #$08; 0x08 == Item picked up sound.
[c6c8]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Pick up the item.
;
[c6cb]a9 0dLDA #$0d; 0xD == Hour Glass.
[c6cd]4c cd c8JMP Player_PickUpItem; Pick it up.

;============================================================================
; Handle picking up the Wing Boots for the quest.
;
; This will invoke the IScript, play the sound, and add
; the Wing Boots to the inventory.
;
; INPUTS:
;     Quests:
;         The player's current completed quests.
;
; OUTPUTS:
;     Quests:
;         The updated set of completed quests.
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Player_PickUpItem
;     Sound_PlayEffect
;
; XREFS:
;     Player_PickUp
;============================================================================
[c6d0]Player_PickUpWingBootsWithQuest:
[c6d0]ad 2d 04LDA a:Quests; Load the completed quests.
[c6d3]09 08ORA #$08; Mark this quest as completed.
[c6d5]8d 2d 04STA a:Quests; Store it back out.

;
; v-- Fall through --v
;

;============================================================================
; Handle picking up the Wing Boots.
;
; This will invoke the IScript, play the sound, and add
; the Wing Boots to the inventory.
;
; INPUTS:
;     None
;
; OUTPUTS:
;     None
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Player_PickUpItem
;     Sound_PlayEffect
;
; XREFS:
;     Player_PickUp
;============================================================================
[c6d8]Player_PickUpWingBoots:
;
; Run the "Got Wing Boots" IScript.
;
; IScript 0x89 via jump to IScripts_Begin.
;
[c6d8]a9 89LDA #$89; 0x89 == Wing boots picked up IScript.
[c6da]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c6dd]0c.byte BANK_12_LOGIC; Bank = 12
[c6de]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Play the sound effect for picking up an item.
;
[c6e0]@_afterFarJump:
[c6e0]a9 08LDA #$08; 0x8 == Item pick-up sound.
[c6e2]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Pick up the item.
;
[c6e5]a9 0fLDA #$0f; 0xF == Wing Boots.
[c6e7]4c cd c8JMP Player_PickUpItem; Pick it up.

;============================================================================
; Pick up the Battle Suit and add to the inventory.
;
; This will invoke the IScript, play the sound, and then
; attempt to cap the armor insert position and add the item
; there.
;
; BUGS:
;     This has a bug where it checks the caps against the
;     WEAPON slots, not the ARMOR slots!
;
;     Player_PickUpDragonSlayer has the inverse
;     bug.
;
; INPUTS:
;     NumberOfWeapons:
;         The number of weapons the player is carrying.
;
; OUTPUTS:
;     ArmorInventory:
;         The updated armor inventory.
;
;     NumberOfArmors:
;         The number of armors in the inventory.
;
;     See CALLS.
;
; CALLS:
;     MMC1_LoadBankAndJump
;     Sound_PlayEffect
;
; XREFS:
;     Player_PickUp
;============================================================================
[c6ea]Player_PickUpBattleSuit:
;
; Run the "Got Battle Suit" IScript.
;
; IScript 0x8B via jump to IScripts_Begin.
;
[c6ea]a9 8bLDA #$8b; 0x8B == Battle Suit picked up IScript.
[c6ec]20 59 f8JSR MMC1_LoadBankAndJump; Run IScript:
[c6ef]0c.byte BANK_12_LOGIC; Bank = 12
[c6f0]41 82pointer IScripts_Begin-1; Address = IScripts_Begin


;
; Play the sound effect for picking up an item.
;
[c6f2]@_afterFarJump:
[c6f2]a9 08LDA #$08; 0x08 == Item picked up sound.
[c6f4]20 e4 d0JSR Sound_PlayEffect; Play it.


;
; Cap the number of WEAPONS in the inventory.
;
; Yes, weapons. This *should* be armor. This code is swapped
; with the code that equips the Dragon Slayer.
;
[c6f7]ae c2 03LDX a:NumberOfWeapons; X = Number of weapons.
[c6fa]e0 04CPX #$04; If < 4
[c6fc]90 02BCC @_addItem; Then, add it to the latest slot.
[c6fe]a2 03LDX #$03; Else, cap X to 3.


;
; Add the Battle Suit to the inventory.
;
[c700]@_addItem:
[c700]a9 03LDA #$03; 0x03 == Battle Suit
[c702]9d a1 03STA a:ArmorInventory,X; Set in the inventory slot


;
; Increase the number of armors collected.
;
[c705]e8INX; X++
[c706]8e c3 03STX a:NumberOfArmors; Store as the number of armors.
[c709]60RTS